在Perl中拆分包含数字的字符串

Question

I want to split a string(which has numerical digits). In the below example, I want to split the string at k and k1.

my @array1=("0","23","1","4","65","7");
$k=1;$k1=0;
my $j=join("",@array1);
my @ar=split(/($k|$k1)/,$j);
print join(";",@ar),"\n\n";

The output is ;0;23;1;4657

In the above output, extra semicolon ";" is printing

The expected output is 0;23;1;4657

When I try the above code for the below example, the output is correct: (0;5;123;4;6) ; the extra semicolon is not printing here.

my @array1=("0","5","1234","6");
$k=5;$k1=4;

I am not sure, for what reason the first example is printing extra semicolon ";"

Can some one help me in this?

Answer 1

The difference is when you split around the first character, you get an empty value at the beginning. Hence the extra ; before the 0 (and after the ""). You'll similarly find ;; when splitting on two adjacent characters

So the absolute simplest fix would be to use grep to remove empty string:

my @ar=split(/($k|$k1)/,$j);
@ar = grep /./, @ar;

This removes the empty strings in @ar.

In the bigger picture, you might want to look at why you're joining strings just to split them back apart. You're also splitting around a number in one place that could appear in another. Like if $k=1 and @array1 = (11, 23, 1, 4);

Answer 2

This is a highly contrived example, has many issues (eg $k and $k1 need to be declared with "my", you should use strict etc.) and it's probably going to do something you don't want.

The bottom line, and the reason you see the leading semicolon, is that if you split by a delimiter that matches at the beginning of the string, split will return an empty list element for that.

print join ';', split /0/, '0123';

Answer 3

There's some interesting behaviour in this code which I was not aware of and that's not been brought out in the other answers. What normally happens with a split on a regular expression is that the characters that you're splitting on are omitted from the result. However, it seems that if you have capturing parentheses in the regex, then the captured material is kept in the result.

Script

#!/usr/bin/env perl

use strict;
use warnings;

my @array1 = ("0", "23", "1", "4", "65", "7");
my $j = join("", @array1);
my $k;
my $k1;
my @ar;
print "Join [$j]\n";

$k = 1;
$k1 = 0;
printf "%-25s", "Version 1 /($k|$k1)/:";
@ar = split(/($k|$k1)/, $j);
print "[", join(";", @ar), "]\n";

printf "%-25s", "Version 2 /($k|$k1)/:";
$k = "1";
$k1 = "0";
@ar = split(/($k|$k1)/, $j);
print "[", join(";", @ar), "]\n";

printf "%-25s", "Version 3 /[01]/:";
@ar = split(/[01]/, $j);
print "[", join(";", @ar), "]\n";

printf "%-25s", "Version 4 /(0|1)/:";
@ar = split(/(0|1)/, $j);
print "[", join(";", @ar), "]\n";

printf "%-25s", "Version 5 /0|1/:";
@ar = split(/0|1/, $j);
print "[", join(";", @ar), "]\n";

printf "%-25s", "Version 6 /([46])/:";
@ar = split(/([46])/, $j);
print "[", join(";", @ar), "]\n";

printf "%-25s", "Version 7 /(?:[46])/:";
@ar = split(/(?:[46])/, $j);
print "[", join(";", @ar), "]\n";

Output

Join [02314657]
Version 1 /(1|0)/:       [;0;23;1;4657]
Version 2 /(1|0)/:       [;0;23;1;4657]
Version 3 /[01]/:        [;23;4657]
Version 4 /(0|1)/:       [;0;23;1;4657]
Version 5 /0|1/:         [;23;4657]
Version 6 /([46])/:      [0231;4;;6;57]
Version 7 /(?:[46])/:    [0231;;57]

As you can see, when the capturing parentheses are present in the regex on which the string is split, the (captured) splitting characters are preserved. When the parentheses are missing or are explicitly non-capturing (Version 7), then the splitting characters are not preserved.

And, if you read the manual carefully, the split description does include the paragraph:

If the PATTERN contains capturing groups , then for each separator, an additional field is produced for each substring captured by a group (in the order in which the groups are specified, as per backreferences ; if any group does not match, then it captures the undef value instead of a substring. Also, note that any such additional field is produced whenever there is a separator (that is, whenever a split occurs), and such an additional field does not count towards the LIMIT.

Followed by some examples.

Testing with Perl 5.16.0 on Mac OS X 10.7.5.

Answer 4

One option is to use a regex instead of split . This works for both data sets you've shown:

use strict;
use warnings;

my @array1 = ( "0", "23", "1", "4", "65", "7" );
my $k      = 1;
my $k1     = 0;

my $j      = join( '', @array1 );
my @ar = $j =~ /([$k$k1]|[^$k$k1]+)/g;
print join( ";", @ar );

Output:

0;23;1;4657

Answer 5

Perl提供了一个非常强大的正则表达式替换构造，在这种情况下，它无需执行split -fu和join -fu：

$string =~ s{(?:$k|$k1)\K}{;}g ;