在Windows环境中编辑文件夹白名单上的文件

Question

I have a folder with ~4000 folders inside of it. In each of these folders is a .ini file that I wish to edit. Inside of the .ini file, I want to search for a string and replace it with another string.

The caveat is that I have a specific list of folders, a whitelist if you will. I only want to change the .ini file inside of the folders I specify in my whitelist and not the rest of the folders.

My platform is Windows.

Example Folder Structure:

Parent Folder
    Folder1
        file.ini
            Variable1=TOMATO
            ^^^^^^^^^^^^^^^^^ > Replace with: Variable1=Lettuce    
    Folder2
        file.ini
            DO NOTHING 
    Folder3
        file.ini
            Variable1=TOMATO
            ^^^^^^^^^^^^^^^^^ > Replace with: Variable1=Lettuce    
    FolderA
        file.ini
            DO NOTHING 
    FolderB
        file.ini
            DO NOTHING 
    FolderC
        file.ini
            Variable1=TOMATO
            ^^^^^^^^^^^^^^^^^ > Replace with: Variable1=Lettuce   

My variable Folder list for the above folder structure would be as follows:

• Folder1
• Folder3
• FolderC

My variables would be:

• Search for: Variable1=TOMATO
• Replace with: Variable1=Lettuce

I tried to use WinGrep and the like, but I only saw one-line excludes versus being able to call a list of folders as above. My production run of this one-time script will pull ~1000 folders out of the list of ~4000, so a manual process is not possible.

Answer 1

A plan (independent of the implementation language):

1. Open the whitelist file for reading
2. For Each non-empty line build a complete/full file spec for the .ini file
3. If the .ini file exists, load it into memory, do the replacement, and write it back

If you want a VBScript version, post some details wrt the .ini file and the replacing.

Update:

VBScript Code to get you started:

  Const csFrom = "Variable1=TOMATO"
  Const csTo = "Variable1=Lettuce"
  Dim oFS  : Set oFS  = CreateObject("Scripting.FileSystemObject")
  Dim sDir : sDir     = oFS.GetAbsolutePathName("..\test\13921972")
  Dim tsFL : Set tsFL = oFS.OpenTextFile(oFS.BuildPath(sDir, "whitelist.txt"))
  Do Until tsFL.AtEndOfStream
     Dim sFSpec : sFSpec = Trim(tsFL.ReadLine())
     If "" <> sFSpec Then
        WScript.Echo "wl:", sFSpec
        sFSpec = oFS.BuildPath(sDir, oFS.BuildPath(sFSpec, "some.ini"))
        WScript.Echo "fs:", sFSpec
        If oFS.FileExists(sFSpec) Then
           Dim sAll : sAll = oFS.OpenTextFile(sFSpec).ReadAll()
           WScript.Echo sAll
           oFS.CreateTextFile(sFSpec, True).Write Replace(sAll, csFrom, csTo)
           WScript.Echo oFS.OpenTextFile(sFSpec).ReadAll()
        End If
     End If
  Loop
  tsFL.Close

output of two runs:

wl: dir1
fs: E:\trials\SoTrials\answers\13415663\test\13921972\dir1\some.ini
Variable0=NoliMeTangere
Variable1=TOMATO
Variable2=NoliMeTangere

Variable0=NoliMeTangere
Variable1=Lettuce
Variable2=NoliMeTangere


wl: dir1
fs: E:\trials\SoTrials\answers\13415663\test\13921972\dir1\some.ini
Variable0=NoliMeTangere
Variable1=Lettuce
Variable2=NoliMeTangere

Variable0=NoliMeTangere
Variable1=Lettuce
Variable2=NoliMeTangere

Answer 2

I'll submit this as a Powershell-solution. It requires static "before" and "after" strings for all files. If this is not the case, you might need to use an hashtable to store the values. As you may see it also requires the whitelist to have one path per line and paths are absolute (ex. C:\\windows)

$before = "this string is getting replaced"
$after = "this is my replacement"
$whitelist = [array](Get-content "path\to\whitelist")

foreach ($path in $whitelist) {
    $files = Get-ChildItem *.ini -Path $path -Recurse
    foreach ($file in $files) {
        (Get-Content $file.fullname).Replace($before,$after) | set-content $file.fullname
    }
}

Whitelist.txt sample:

C:\test\whats up
C:\test\1
C:\test\2