如何使用Excel VBA 2007在XML中添加图像标签

Question

I am generating xml using excel 2007 vba. After executing macro, I am getting this output

but I need output like

I dont want &lt and &gt instead of < and > tags. The macro that I am using is

enter code here

Dim xmlDoc As New MSXML2.DOMDocument30
Dim objNode As MSXML2.IXMLDOMNode
Dim personNode As MSXML2.IXMLDOMNode
Dim imagesNode As MSXML2.IXMLDOMNode
Set objNode = xmlDoc.createNode(NODE_PROCESSING_INSTRUCTION, "xml", "")
xmlDoc.appendChild objNode
Set objNode = xmlDoc.createNode(NODE_ELEMENT, "root", "")
Set personNode = xmlDoc.createNode(NODE_ELEMENT, "person", "")
objNode.appendChild personNode
Set imagesNode = xmlDoc.createNode(NODE_ELEMENT, "images", "")
personNode.appendChild imagesNode
imagesNode.Text = "<image href=" & Chr(34) & "file:///Users/d.jahr/Desktop/XML           Booklet/Bilder/pic1.jpg" & Chr(34) & "/>"
xmlDoc.appendChild objNode
Set objNode = Nothing
MsgBox xmlDoc.XML
xmlDoc.Save ActiveWorkbook.Path & "\" & "result.xml"

End Sub

Please help me.

Thanks

Answer 1

Rather than set the text of the images collection, consider appending an image child node and setting the href attribute of it:

Sub test()
    Dim xmlDoc As New MSXML2.DOMDocument30
    Dim objNode As MSXML2.IXMLDOMNode
    Dim personNode As MSXML2.IXMLDOMNode
    Dim imagesNode As MSXML2.IXMLDOMNode

    Dim image1Node As MSXML2.IXMLDOMNode
    Dim namedItem As Object

    Set objNode = xmlDoc.createNode(NODE_PROCESSING_INSTRUCTION, "xml", "")
    xmlDoc.appendChild objNode
    Set objNode = xmlDoc.createNode(NODE_ELEMENT, "root", "")
    Set personNode = xmlDoc.createNode(NODE_ELEMENT, "person", "")
    objNode.appendChild personNode
    Set imagesNode = xmlDoc.createNode(NODE_ELEMENT, "images", "")
    personNode.appendChild imagesNode

    Set image1Node = xmlDoc.createNode(NODE_ELEMENT, "image", "")
    imagesNode.appendChild image1Node
    Set namedItem = xmlDoc.createAttribute("href")
    namedItem.Value = "file:///Users/d.jahr/Desktop/XMLBooklet/Bilder/pic1.jpg"
    image1Node.Attributes.setNamedItem namedItem

    xmlDoc.appendChild objNode
    Debug.Print xmlDoc.XML
End Sub

Output:

<?xml version="1.0"?>
<root>
   <person>
      <images>
         <image href="file:///Users/d.jahr/Desktop/XMLBooklet/Bilder/pic1.jpg"/> 
      </images>
   </person>
</root>