根据范围内的数据组织/分类工作簿表

Question

I need to sort some worksheets in Excel 2010 according to a specific rule. In the workbook where the macro runs (Workbook_0) I have a list of words, all in one row, one per column, for example

• A:"mango" B:"apple" C:"banana". I save this range in a variable of type Range.

My macro creates a new workbook (Workbook_1) with sheets called, for example,

• "apple_count", "apple_avg", "banana_count", "banana_average", "mango_count", "mango_avg".

What I would like to do is to sort the sheets in Workbook_1 according to the order specified in Workbook_0. In the example, I would obtain

• "mango_count", "mango_avg", "apple_count", "apple_avg", "banana_count", "banana_avg".

To make life easier I know for sure that Workbook_1 will only have sheets whose names are contained in Workbook_0. Even though it might be fair to ask why I don't sort the sheets in Workbook_1 as I create them, that's not what I need to do. I'm not exactly sure how to go about this without making an inefficient and hard to debug code.

Any help is greatly appreciated! Thanks!

UPDATE: @MattCrum solution works very well. Here is my final code which include a few modifications (ignores case, fixed a bug, output to a different workbook, moves additional sheets):

Dim rngTemp As Range, rngAll as Range
Dim shtTemp As Worksheet, shtFound As Worksheet

Set rngAll = Range("A1:A3")
Set shtFound = Sheets(1)

' Sort _count sheets
For Each rngTemp In rngAll
    For Each shtTemp In Workbooks(OutputFileName).Worksheets
        If LCase(shtTemp.Name) = LCase(rngTemp.Value) & "_count" Then
            shtTemp.Move , shtFound
            Set shtFound = shtTemp
        End If
    Next
Next

' Move _avg sheets to the right of correctly ordered _count sheets
For Each rngTemp In rngAll
    For Each shtTemp In Workbooks(OutputFileName).Worksheets
        If LCase(shtTemp.Name) = LCase(rngTemp.Value) & "_time" Then
            shtTemp.Move , Sheets(LCase(rngTemp.Value) & "_count")
        End If
        If LCase(shtTemp.Name) = LCase(rngTemp.Value) & "_avg" Then
            shtTemp.Move , Sheets(LCase(rngTemp.Value) & "_time")
        End If
    Next
Next

Answer 1

Here's a fairly simple way to do it - not sure how fast it'll be if you have a lot of sheets but give it a go:

Sub SortSheets()

Dim rngAll As Range, rngTemp As Range
Dim shtTemp As Worksheet, shtFound As Worksheet

Set rngAll = Sheet1.Range("A1:A3")
Set shtFound = Sheets(1)

'Sort _count sheets

    For Each rngTemp In rngAll
        For Each shtTemp In ThisWorkbook.Worksheets
            If shtTemp.Name = rngTemp.Value & "_count" Then
                shtTemp.Move , shtFound
                Set shtFound = shtTemp
            End If
        Next
    Next

'Move _avg sheets to the right of correctly ordered _count sheets

    For Each rngTemp In rngAll
        For Each shtTemp In ThisWorkbook.Worksheets
            If shtTemp.Name = rngTemp.Value & "_avg" Then
                shtTemp.Move , Sheets(rngTemp & "_count")
            End If
        Next
    Next

End Sub