erlang生成过程错误？

Question

我正在按照本教程进行操作，并尝试编译event.erl并根据

6> c(event).
{ok,event}
7> rr(event, state).
[state]
8> spawn(event, loop, [#state{server=self(), name="test", to_go=5}]).
<0.60.0>
9> flush().
ok
10> flush().
Shell got {done,"test"}
ok
11> Pid = spawn(event, loop, [#state{server=self(), name="test", to_go=500}]).
<0.64.0>
12> ReplyRef = make_ref().
#Ref<0.0.0.210>
13> Pid ! {self(), ReplyRef, cancel}.
{<0.50.0>,#Ref<0.0.0.210>,cancel}
14> flush().
Shell got {#Ref<0.0.0.210>,ok}
ok

但是我似乎无法通过第8步，因为我收到了此错误。

7> spawn(event, loop, [#state{server=self(), name="test", to_go=5}]).

=ERROR REPORT==== 14-Feb-2013::11:14:38 ===
Error in process <0.51.0> with exit value: {function_clause,[{event,loop,[{state,<0.32.0>,"test",5}],[{file,"event.erl"},{line,35}]}]}

<0.51.0>

以下是event.erl

-module(event).
-export([start/2, start_link/2, cancel/1]).
-export([init/3, loop/1]).
-record(state, {server,
                name="",
                to_go=0}).

%%% Public interface
start(EventName, DateTime) ->
    spawn(?MODULE, init, [self(), EventName, DateTime]).

start_link(EventName, DateTime) ->
    spawn_link(?MODULE, init, [self(), EventName, DateTime]).

cancel(Pid) ->
    %% Monitor in case the process is already dead
    Ref = erlang:monitor(process, Pid),
    Pid ! {self(), Ref, cancel},
    receive
        {Ref, ok} ->
            erlang:demonitor(Ref, [flush]),
            ok;
        {'DOWN', Ref, process, Pid, _Reason} ->
            ok
    end.

%%% Event's innards
init(Server, EventName, DateTime) ->
    loop(#state{server=Server,
                name=EventName,
                to_go=time_to_go(DateTime)}).

%% Loop uses a list for times in order to go around the ~49 days limit
%% on timeouts.
loop(S = #state{server=Server, to_go=[T|Next]}) ->
    receive
        {Server, Ref, cancel} ->
            Server ! {Ref, ok}
    after T*1000 ->
        if Next =:= [] ->
            Server ! {done, S#state.name};
           Next =/= [] ->
            loop(S#state{to_go=Next})
        end
    end.

%%% private functions
time_to_go(TimeOut={{_,_,_}, {_,_,_}}) ->
    Now = calendar:local_time(),
    ToGo = calendar:datetime_to_gregorian_seconds(TimeOut) -
           calendar:datetime_to_gregorian_seconds(Now),
    Secs = if ToGo > 0  -> ToGo;
              ToGo =< 0 -> 0
           end,
    normalize(Secs).

%% Because Erlang is limited to about 49 days (49*24*60*60*1000) in
%% milliseconds, the following function is used
normalize(N) ->
    Limit = 49*24*60*60,
    [N rem Limit | lists:duplicate(N div Limit, Limit)].

编辑：我试图通过从此添加一个参数来更改函数循环

loop(S = #state{server=Server, to_go=[T|Next]}) ->

to this 

loop(S = #state{server=Server,name=EventName, to_go=[T|Next]}) ->

并且它仍然可以编译，但是它不起作用，同样的错误...我想也许是元组不匹配。 然后只会演变为参数to_go=[T|Next]}不正确。

Answer 1

我认为问题在于您的loop / 1子句将#state参数解包，从而使to_go与列表进行模式匹配（即，to_go = [T | Next]）。 但是，您传入了一个5（to_go = 5），它将无法匹配[T | Next]因此，循环/ 1将不匹配，并且您将没有匹配的函数子句

loop(#state{server=self(), name="test", to_go=5})

Answer 2

该表达式：

8> spawn(event, loop, [#state{server=self(), name="test", to_go=5}]).

适用于较早版本的代码，因为它是在整个教程中开发的。 如果我正确阅读，这应该是正确的电话：

19> event:start("Event", 0).

Answer 3

这与Erlang处理事件错误中的问题相同。 start/2 ， start_link/2和time_to_go/1函数需要一个{{Year,Month,Day},{Hour,Minute,Second}}形式的时间参数，这就是为什么当您用5调用它们时它们会失败的原因。 loop/1函数期望#state{}的to_go字段是一个整数列表，它将解释为秒，并将通过对每个整数进行一次receive...after来等待总时间。 该服务器的目标是能够比Erlang在receive...after直接等待更长的时间。

time_to_go/1函数正在计算从现在开始到作为参数输入的日期/时间之间的秒数，然后将其细分为一个秒数列表，其中秒数不大于receive...after可以处理的最大大小。