通过议程编写和调用函数（组织模式）

Question

（我不懂lisp，所以我怀疑这真的很简单。）

我想编写一个函数来简化我的组织模式和GTD设置。

我的组织模式设置基于以下内容： http : //doc.norang.ca/org-mode.html#CustomAgendaViewSetup

我想对多个标签使用“ NEXT”设置（见下文）-我可以简单地一遍又一遍地剪切和粘贴相同的代码，但是编写一个函数会更加干净，而不是拥有这个：

            (tags-todo "-WAITING-CANCELLED/!NEXT"
                       ((org-agenda-overriding-header "Next Tasks")
                        (org-agenda-skip-function 'bh/skip-projects-and-habits-and-single-tasks)
                        (org-agenda-todo-ignore-scheduled 'future)
                        (org-agenda-todo-ignore-deadlines 'future)
                        (org-tags-match-list-sublevels t)
                        (org-agenda-sorting-strategy
                         '(todo-state-down effort-up category-keep))))

我更喜欢这样的东西：

            (MyFunction "@work")
            (MyFunction "@computer")

该函数的参数将上述代码块中的过滤更改为：

            (tags-todo "-WAITING-CANCELLED+<XXX>/!NEXT"

即

            (tags-todo "-WAITING-CANCELLED+@work/!NEXT"

有人可以帮我指出正确的方向吗？

Answer 1

以下应该可以解决问题（它还包含一个变量，用于测试在标记之前使用+还是- ，默认为- ）。

(defun zin/agenda-test (tag &optional signp)
  "Simplify agenda coding, only require TAG to create new block.

SIGNP determines whether to use `+' or `-' when adding the tag.
Defaulting to `-'."
  (let ((sign (if signp "+" "-")))
    `(tags-todo ,(format "-WAITING-CANCELLED%s%s/!NEXT" sign tag)
        ((org-agenda-overriding-header "Next Tasks")
         (org-agenda-skip-function 'bh/skip-projects-and-habits-and-single-tasks)
         (org-agenda-todo-ignore-scheduled 'future)
         (org-agenda-todo-ignore-deadlines 'future)
         (org-tags-match-list-sublevels t)
         (org-agenda-sorting-strategy
          '(todo-state-down effort-up category-keep))))))

(setq org-agenda-custom-commands `(("t" "Test"
                                (,(zin/agenda-test "@tag")
                                 ,(zin/agenda-test "@test" '+)))))

您必须确保org-agenda-custom-commands使用反引号语法（ ` ）而不是(quote ...) ，否则命令将无法正确扩展。