如何将SPARQL查询的结果重用于另一个查询？

Question

例如我有这个查询

SELECT ?x
WHERE {?x :has_input "z"}

然后我想使用?x的结果作为另一个查询的对象

SELECT ?y
WHERE {?y :uses "x"}

有什么想法要实现吗？ 提前致谢

Answer 1

为了举例说明，让我们定义一些数据：

@prefix : <http://example.org/> .

:node0 :has_input "w", "z" .
:node1 :has_input "x", "y" .
:node2 :has_input "y", "z" .
:node3 :uses :node2 .
:node4 :uses :node1 .

基于此数据，并指定了任何特定的API（因为没有指定），您就有了一些SPARQL级别的选项。 首先是简单地组合查询，在这种情况下这很容易：

prefix : <http://example.org/>

select ?y where { 
  ?x :has_input "z" .
  ?y :uses ?x .
}

$ arq --data data.n3 --query combined-query.sparql 
----------
| y      |
==========
| :node3 |
----------

另一种选择是使用子查询

prefix : <http://example.org/>

select ?y where { 
  {
    select ?x where { 
      ?x :has_input "z" .
    }
  }
  ?y :uses ?x .
}


$ arq --data data.n3 --query subquery.sparql
----------
| y      |
==========
| :node3 |
----------

第三种可能是您实际需要的，如果您必须分别执行查询，则是执行一个查询，该查询为您找到?x值，然后执行一个查询，找到?y ，但带有?x值嵌入values 。 第一个查询如下所示，并返回：

prefix : <http://example.org/>

select ?x where { 
  ?x :has_input "z" .
}

$ arq --data data.n3 --query xquery.sparql
----------
| x      |
==========
| :node2 |
| :node0 |
----------

然后，基于这些值，为?y创建查询：

prefix : <http://example.org/>

select ?y where { 
  values ?x { :node2 :node0 }
  ?y :uses ?x .
}

$ arq --data data.n3 --query yquery.sparql
----------
| y      |
==========
| :node3 |
----------