Excel VBA复制和粘贴循环内的循环

Question

我已经在VBA代码上工作了一段时间了，由于我是一个完整的菜鸟，所以我觉得自己什么都没得到。 我一直在研究大量内容，但似乎无法结合答案来帮助解决我的情况。

本质上，我想做的是从一个工作表中逐行获取数据，并将其外推到另一个工作表。 我相信这会涉及循环，而我对VBA还是很陌生，我不知道该怎么做。

这是我尝试的逻辑：对于工作表1的每一行，我想对工作表2执行3种不同的复制和粘贴活动，然后它将循环到sheet1的下一行并执行这3项活动，依此类推。 这将继续向下，直到工作表1中的A列为空白。 Sheet1数据从A3开始，Sheets2粘贴区域从A2开始。

第一个活动是将单元格F3，D3，A3和H3（以此顺序将F3复制为A2，D3为B2等）从工作表1复制到工作表2，再复制到A2，B2，C2等。目标函数可以不会被使用，因为我只需要值而无需其他格式，这是我遇到的许多问题之一。

下一个活动是将单元格F3，D3，A3和I3从工作表1复制到粘贴在先前复制下面的工作表2，然后粘贴-同样，没有格式只是值。 还要注意，其中一些可能为空（A列除外），但是我仍然需要至少包含A列数据的那一行-包括所有这些活动。

第三个活动是将工作表1的F3，D3和A3复制并粘贴一定的次数（参考K3的编号），并且每次复制和粘贴都将在下一个可用的空白单元格中。 因此，如果K3中的数字看起来像是在sheet2中创建了3行-由于activity1和2各自创建了自己的行，因此在sheet2上总共添加了5行。

在工作表1的第3行完成这三个活动之后，它将移至行4并执行前面的三个活动并粘贴到工作表2。 再一次，它将不粘贴任何格式，并粘贴在工作表2的下一个空白行中。同样，一旦列A中的单元格为空白，此循环将停止。

下面是我不完整的代码。 我什至不认为这会有所帮助，甚至最好不要看它。 因为我什至无法进行简单的复制和粘贴，但是在循环中独自循环，我才开始感到沮丧。 我什至还没有开始我的第三项活动。 我非常感谢！

Sub copyTest3()

Dim proj As Range, release As Range, pm As Range, lead As Range, coord As Range
Dim leadCopy As Range, coordCopy As Range
Dim i As Range

Set proj = Range("A3", Range("A3").End(xlDown))
Set release = Range("D3", Range("D3").End(xlDown))
Set pm = Range("F3", Range("F3").End(xlDown))
Set lead = Range("H3", Range("H3").End(xlDown))
Set coord = Range("I3", Range("I3").End(xlDown))

Set leadCopy = Union(pm, release, proj, lead)
Set coordCopy = Union(pm, release, proj, coord)


For i = 1 To Range(ActiveSheet.Range("A3"), ActiveSheet.Range("A3").End(xlDown))
    leadCopy.Copy
    Sheets("Sheet2").Activate
    Range("A2").Select
    ActiveSheet.PasteSpecial xlPasteValues

    Application.CutCopyMode = False

    Sheets("Sheet1").Activate
    coordCopy.Copy
    Sheets("Sheet2").Activate
    Range("A2").Select
    ActiveSheet.PasteSpecial xlPasteValues

Next i

End Sub

Answer 1

我通常在Excel中的工作表之间复制数据的方法是创建源范围和目标范围对象，每个范围仅引用一行。 当我想移至下一行时，我使用Offset将范围偏移返回到下一行。

由于范围仅引用一行，因此您可以使用整数对它们进行索引以获取该行中的单元格。 例如，如果cursor指向第3行的A到D列， cursor(3)将为您提供单元格C3。

Dim src_cursor As Range
Dim dest_cursor As Range

Set src_cursor = ActiveSheet.Range("A3:I3")
Set dest_cursor = Sheets("Sheet2").Range("A2:D2")

'' Loop until column A is empty in source data
Do Until IsEmpty(src_cursor(1))
    dest_cursor(1) = src_cursor(6) '' copy F -> A
    dest_cursor(2) = src_cursor(4) '' copy D -> B
    '' and so on

    '' move cursors to next row
    Set src_cursor = src_cursor.Offset(1, 0)
    Set dest_cursor = dest_cursor.Offset(1, 0)
Loop

同样，这可能会有些偏离主题，但是最好使用Enum命名列号，而不是像我在此处那样对其进行硬编码。

Answer 2

有许多方法可以做到这一点，有些方法比其他方法更有效。 我的解决方案可能不是最有效的，但是希望您可以轻松理解它，以便您学习。

很难理解您在活动三中要做什么，因此我无法为该步骤提供解决方案。 将我的代码用作第三步的模板，如果遇到问题，请随时发表评论。

注意，在此代码中我没有使用.Activate ， .Select或.Copy 。 .Activate和.Select是巨大的效率杀手，它们使您的代码更容易“破坏”，因此请尽可能避免使用它们。 .Copy在使用值或公式时不是必需的，并且还会降低代码速度。

未经测试

Sub testLoopPaste()

Dim i As Long
Dim ii As Long
Dim i3 as Long
Dim LastRow As Long
Dim wb As Workbook
Dim sht1 As Worksheet
Dim sht2 As Worksheet

Set wb = ThisWorkbook
Set sht1 = wb.Sheets("Sheet1")
Set sht2 = wb.Sheets("Sheet2")

'Find the last row (in column A) with data.
LastRow = sht1.Range("A:A").Find("*", searchdirection:=xlPrevious).Row
ii = 2

'This is the beginning of the loop
For i = 3 To LastRow
    'First activity
    sht2.Range("A" & ii) = sht1.Range("F" & i).Value
    sht2.Range("B" & ii) = sht1.Range("D" & i).Value
    sht2.Range("C" & ii) = sht1.Range("A" & i).Value
    sht2.Range("D" & ii) = sht1.Range("H" & i).Value
    ii = ii + 1

    'Second activity
    sht2.Range("A" & ii) = sht1.Range("F" & i).Value
    sht2.Range("B" & ii) = sht1.Range("D" & i).Value
    sht2.Range("C" & ii) = sht1.Range("A" & i).Value
    sht2.Range("D" & ii) = sht1.Range("I" & i).Value
    ii = ii + 1

    'Third activity
    For i3 = 1 To sht1.Range("K" & I)  
        sht2.Range("A" & ii) = sht1.Range("F" & i).Value  
        sht2.Range("B" & ii) = sht1.Range("D" & i).Value  
        sht2.Range("C" & ii) = sht1.Range("A" & i).Value  
        ii = ii + 1  
    Next i3

Next i

End Sub