来自Training的Neo4j密码查询

Question

我刚刚在http://www.neo4j.org/learn/online_course上完成了培训，并对实验室答案有几个问题。

首先是来自第2课的高级图形实验室。（未给出答案，并且未在图形小部件thingie中进行验证）

问题是：推荐基努·里维斯应与之合作的3位演员（但没有）。 提示是，您基本上应该选择与Keanu还没有ACTED_IN的电影具有ACTED_IN关系的三个人物。

该图包含具有ACTED_IN关系和DIRECTED关系的Person节点和Movie节点。

我想出了这个：

MATCH (a:Person)-[:ACTED_IN]->(movie:Movie)
WHERE NOT (:Person {name:"Keanu Reeves"})-[:ACTED_IN]->(movie)
RETURN a, count(movie)
ORDER BY count(movie) DESC
LIMIT 3

但我无法确定这是否真的排除了同一部电影，还是只排除了基努·里维斯（因为基恩努的电影中没有回返的演员，但无论如何他们可能都已经回了。

Answer 1

到目前为止，我已经找到了两个解决方案。

1：推荐最忙的演员基努·里夫斯（Keanu Reeves）未曾与之合作。

MATCH (p:Person)-[:ACTED_IN]->(m)
WHERE p.name <> 'Keanu Reeves'
AND NOT (p)-[:ACTED_IN]->()<-[:ACTED_IN]-(:Person{name:'Keanu Reeves'})
RETURN p.name, count(m) AS rating
ORDER BY count(m) DESC
LIMIT 3;

哪个产量

p.name          | rating
--------------------------
Tom Hanks       | 12
Meg Ryan        | 5
Cuba Gooding Jr.| 4

2：推荐演员基努·里维斯（Keanu Reeves）的主演与大多数人合作

MATCH (f:Person)-[:ACTED_IN]->(m)<-[:ACTED_IN]-(c:Person),
(k:Person{name:'Keanu Reeves'})
WHERE c.name <> 'Keanu Reeves'
AND (f)-[:ACTED_IN]->()<-[:ACTED_IN]-(k)
AND NOT (c)-[:ACTED_IN]->()<-[:ACTED_IN]-(k)
RETURN c.name, count(c) AS  Rating
ORDER BY Rating desc
LIMIT 3;

哪个产量

p.name          | rating
--------------------------
Danny DeVito    | 2
J.T. Walsh      | 2
Tom Hanks       | 2

Answer 2

今天我遇到了这个问题，在这里我做了什么

MATCH (keanu:Person)-[:ACTED_IN]->(movie),
      (playedwith:Person)-[:ACTED_IN]->(movie), 
      (playedwith)-[t:ACTED_IN]->(othermovie),
      (other:Person)-[:ACTED_IN]->(othermovie)
WHERE keanu.name = "Keanu Reeves"
      AND NOT (other)-[:ACTED_IN]->(movie)
      AND NOT (keanu)-[:ACTED_IN]->(othermovie)
RETURN other.name
      ,collect(DISTINCT othermovie)
      ,collect(DISTINCT playedwith)
      ,count(DISTINCT playedwith)
ORDER BY count(DISTINCT playedwith)desc
LIMIT 3

由于Distict太多，我虽然不喜欢它，但结果如下：

other.name    | collect(DISTINCT othermovie) | collect(DISTINCT playedwith)        | count(DISTINCT playedwith)
-----------------------------------------------------------------------------------------------------------------------------
Tom Hanks     | ["Cloud Atlas",              | ["Hugo Weaving","Charlize Theron"]  | 2
              |  "That Thing You Do"]        |
Tom Cruise    | ["A Few Good Men"]           | ["Jack Nicholson"]                  | 1
Robin Williams| ["The Birdcage"]             | ["Gene Hackman"]                    | 1

Answer 3

因此，我发现了两种看起来不错的不同方法。 第一个查找具有“ ACTED_IN同一部电影”最多的人，其原始人不是与Keanu Reeves有“ ACTED_IN同一部电影”关系的人。

第二个查找的人尚未与Keanu Reeves交流过电影，但按照参与最多电影的人排序。

当然，在共享此关系的所有演员之间创建“ WORKED_WITH”关系，然后搜索Keanu尚未使用WORKED_WITH的所有人，这将是最简单的方法，但这使我猜错了。

第一个解决方案非常简单，而且看起来非常准确：

MATCH (a:Person {name:"Keanu Reeves"})-[:ACTED_IN]->(:Movie)<-[:ACTED_IN]-(b:Person)
WITH collect(b.name) AS FoF
MATCH (c:Person)-[:ACTED_IN]->(:Movie)<-[:ACTED_IN]-(d:Person)
WHERE not c.name IN FoF AND c.name <> "Keanu Reeves"
RETURN distinct c.name, count(distinct d)
ORDER BY count(distinct d) desc
limit 3

它返回：

c.name          | count(distinct d)
-------------------------------
Tom Hanks       |    34
Cuba Gooding Jr.|    24
Tom Cruise      |    23

d是c拥有“ ACTED_IN”的人数。

---

编辑添加：

在给出答案后，我使用了更为简化的查询方法来提出以下建议：

MATCH (a:Person)-[:ACTED_IN]->()<-[:ACTED_IN]-(b:Person)
WHERE a.name <>'Keanu Reeves' 
AND NOT (a)-[:ACTED_IN]->()<-[:ACTED_IN]-(b:Person {name:'Keanu Reeves'})
RETURN a.name, count(Distinct b) AS Rating
ORDER BY Rating DESC
LIMIT 3

返回与上面相同的内容。

---

或者，我将这些用于大多数电影中工作过的人：

MATCH (a:Person {name:"Keanu Reeves"})-[:ACTED_IN]->(:Movie)<-[:ACTED_IN]-(b:Person)
WITH collect(b.name) AS FoF
MATCH (c:Person)-[:ACTED_IN]->(m:Movie)<-[:ACTED_IN]-(d:Person)
WHERE not c.name IN FoF AND c.name <> "Keanu Reeves"
RETURN distinct c.name, count(distinct m)
ORDER BY count(distinct m) desc
limit 3

返回：

c.name           |  count(distinct m)
-------------------------------------------
Tom Hanks        |  11
Meg Ryan         |  5
Cuba Gooding Jr. |  4

其中m是他们制作的电影数量。