AS3 Flash键盘事件空格键问题

Question

大家好，非常感谢您的帮助

好的，问题是这样的。 我正在尝试自动移动动画片段

movieClip.x += xspeed ; 

当然这可行，但问题在于我希望通过按下键盘来触发..问题是我无法进行键盘事件，就像鼠标点击一样。 .it停止工作。.我希望它像onclick一样应该开始自动移动。

有任何想法吗？ 谢谢

您好，非常感谢您的答复，对于您的延迟深表歉意。 您的代码给了我一个主意，但我尝试不使用类来编写它。 它不会引发任何错误，但是也不起作用。 我一定在做些蠢事，请看一眼，让我知道。 //绳编码

var ropey = MovieClip(this.root).boat_mc.rope_mc.fishyrope_mc.hitbox_mc.y ;
    trace(ropey);
    var ropemove:Boolean;


    stage.addEventListener(Event.ENTER_FRAME,ropeCode);

    function ropeCode(e:Event):void
    {
                //detect keyboard spacebar click
                stage.addEventListener(KeyboardEvent.KEY_UP,onSpacebarUp);

                function onSpacebarUp(e:KeyboardEvent):void
                {
                    if (e.keyCode == Keyboard.SPACE)
                    {
                        ropemove = true;
                    } else if(ropey > 600 ) {
                        ropemove = false;
                    }

                }

                    //drop rope if variable = true

                    function dropRope(e:Event):void 
                    {

                        if(ropemove = true) {
                            MovieClip(this.root).boat_mc.rope_mc.y += xSpeed;
                        } else if (ropemove = false) {
                            MovieClip(this.root).boat_mc.rope_mc.y -= xSpeed;
                        }
                    }



    }

Answer 1

MyObj扩展了MovieClip （或Sprite ）。 基本上所有发生的事情是，您应该在获取KEY_UP时切换一个变量（而不是KEY_DOWN ，因为如果按住该键将重复该操作）。 然后，在每一帧中检查此变量，如果很好，请移动

就像是：

private var m_shouldMove:Boolean = false;

// constructor
public function MyObj()
{
    // add our listener for when we're added to the stage as we'll be adding events on it
    this.addEventListener( Event.ADDED_TO_STAGE, this._onAddedToStage );
}

private function _onAddedToStage( e:Event ):void
{
    // NOTE: the keyboard listener goes onto the stage
    // you'll also need to remove the events when your object is removed (e.g. REMOVED_FROM_STAGE)
    this.removeEventListener( Event.ADDED_TO_STAGE, this._onAddedToStage );
    this.addEventListener( Event.ENTER_FRAME, this._onEnterFrame );
    this.stage.addEventListener( KeyboardEvent.KEY_UP, this._onKeyUp );
}

private function _onEnterFrame( e:Event ):void
{
    // every frame, if we should move, do so
    if( this.m_shouldMove )
        this.x += this.speed;
}

private function _onKeyUp( e:KeyboardEvent ):void
{
    if( e.keyCode == Keyboard.SPACE )
        this.m_shouldMove = !this.m_shouldMove; // toggle our var
}

更新

我对您的代码示例进行了重新设计，因此现在应该可以正常工作：

var rope = MovieClip(this.root).boat_mc.rope_mc.fishyrope_mc.hitbox_mc;
var ropeMove:Boolean = false;

stage.addEventListener(Event.ENTER_FRAME, ropeCode);
stage.addEventListener(KeyboardEvent.KEY_UP, onSpacebarUp);

function onSpacebarUp(e:KeyboardEvent):void
{
    if (e.keyCode == Keyboard.SPACE)
        ropeMove = !ropeMove; // toggles ropeMove (i.e. if it's true, sets it to false, and vice versa)
}

function ropeCode(e:Event):void
{
    // move the rope
    if( ropeMove )
    {
        rope.y += xSpeed;

        // stop moving if we've gone too far
        if( rope.y > 600.0 )
        {
            rope.y = 600.0;
            ropeMove = false;
        }
    }
}

我改变了什么：

• 将绳索作为变量握住，以方便操作
• 删除了ropey因为它不是必需的（对于> 600.0检查，您仍然需要重新计算）
• 现在，键盘事件与Enter frame事件一起添加（您在每个帧中添加了一个新的键盘事件
• 键盘事件侦听器只需切换ropeMove var（此处不检查> 600.0 ，因为这意味着您仅在按下任何其他键时进行检查）
• Enter框事件仅使绳索y移动
• 在回车事件中，如果我们的y太大，我们将停止移动

代码在做什么：

• 我们建立了我们瓦尔- rope和ropeMove - ropeMove是用于了解，如果我们可以将绳子或不
• 我们添加了事件监听器-一个用于keybard事件，用于捕获空格键，另一个用于输入frame事件，因此如有必要，我们可以移动绳索
• 在键盘事件中，如果我们的键是空格键，则切换我们的ropeMove变量
• 在enter frame事件中，如果ropeMove为true，我们将移动绳索
• 如果rope.y大于600，则将其钳位到600，然后将ropeMove设置为false以便我们停止移动

更新2

通过添加可变的ropeDir ，绳索现在将连续不断地上下移动（假设ropeMove为true ）

var rope = MovieClip(this.root).boat_mc.rope_mc.fishyrope_mc.hitbox_mc;
var ropeMove:Boolean = false;
var ropeDir:int = 1;

stage.addEventListener(Event.ENTER_FRAME, ropeCode);
stage.addEventListener(KeyboardEvent.KEY_UP, onSpacebarUp);

function onSpacebarUp(e:KeyboardEvent):void
{
    if (e.keyCode == Keyboard.SPACE)
        ropeMove = !ropeMove; // toggles ropeMove (i.e. if it's true, sets it to false, and vice versa)
}

function ropeCode(e:Event):void
{
    // move the rope
    if( ropeMove )
    {
        rope.y += xSpeed * ropeDir;

        // stop moving if we've gone too far
        if( rope.y > 600.0 && ropeDir == 1 )
            ropeDir = -1;
        else if( rope.y < 0.0 && ropeDir == -1 )
            ropeDir = 1;
    }
}

Answer 2

addEventListener(KeyboardEvent.KEY_DOWN, moveStarter);

function moveStarter():void
{
   addEventListener(Event.ENTER_FRAME, startMove);
}