Clojure-使用过滤器

Question

我正在尝试遍历地图以计算单个事件的特定发生次数，尽管在使用以下过滤器时遇到了一些麻烦。 我想要做的是过滤并计算每个“ ORDER_CATEGORY”的特定实例，这些实例以多个级别（1、2等）出现。 我可以遍历月份并进行打印，但可以过滤并计算ORDER_CATEGORY的计数，这似乎对我不起作用。

 GROUPED_BY_MONTH(group-by :MONTH CON)

 ALL (for [flop GROUPED_BY_MONTH] {
    :MONTH  (:MONTH (first (second flop)))
    :ORDER1 (count (filter #(= "1" (:ORDER_CATEGORY %)) flop))
    :ORDER2 (count (filter #(= "2" (:ORDER_CATEGORY %)) flop))
})

我正在处理XML文件，这些文件已成功地管理到一个串联列表中，并按以下方式分组：

[“ 01” [{：MONTH“ 01”，：ORDER_CATEGORY“ 1”} {：MONTH“ 01”，：ORDER_CATEGORY“ 1”} {：MONTH“ 01”，：ORDER_CATEGORY“ 2”}]] [“ 02” [{：MONTH“ 02”，：ORDER_CATEGORY“ 1”} {：MONTH“ 02”，：ORDER_CATEGORY“ 2”} {：MONTH“ 02”，：ORDER_CATEGORY“ 2”}]]

因此，我希望有：

MONTH ORDER1 ORDER2

01 -------- 2 -------------- 1

02 -------- 1 -------------- 2

这可能是我忽略的相对简单的修复程序，因此感谢您的提前帮助！

Answer 1

我首先将数据转换为：

user=> (pprint x)
[{:MONTH "01", :ORDER_CATEGORY "1"}
 {:MONTH "01", :ORDER_CATEGORY "1"}
 {:MONTH "01", :ORDER_CATEGORY "2"}
 {:MONTH "02", :ORDER_CATEGORY "1"}]

并使用功能：

user=> (defn inc1 [x] (if x (inc x) 1))
user=> (reduce (fn [acc {:keys [MONTH ORDER_CATEGORY]}]
                     (update-in acc [[MONTH ORDER_CATEGORY]] inc1)) {} x)
{["02" "1"] 1, ["01" "2"] 1, ["01" "1"] 2}

关键是[月份类别]，值是订单数。

Answer 2

您的for循环不起作用，因为您已将这样的映射项绑定到flop

["01" [{:MONTH "01", :ORDER_CATEGORY "1"} ...]]

您的过滤器表达式会将其作为输入：

(filter #(= "1" (:ORDER_CATEGORY %)) flop)

这将不起作用，因为:ORDER_CATEGORY都不会返回sth。 表示"01" ，也不表示序列[{:MONTH ...} ...] 。

鉴于绑定到flop是MapEntry，可以使用val来解决此问题：

(filter #(= "1" (:ORDER_CATEGORY %)) (val flop)) 。

例如：

(for [flop GROUPED_BY_MONTH]
  {:MONTH  (:MONTH (first (second flop)))
   :ORDER1 (count (filter #(= "1" (:ORDER_CATEGORY %)) (val flop)))
   :ORDER2 (count (filter #(= "2" (:ORDER_CATEGORY %)) (val flop)))})
=> ({:MONTH "01", :ORDER1 2, :ORDER2 1} {:MONTH "02", :ORDER1 1, :ORDER2 0})

您还可以使用析构函数使代码更清晰：

(for [[month maps] GROUPED_BY_MONTH]
  {:MONTH month
   :ORDER1 (count (filter #(= "1" (:ORDER_CATEGORY %)) maps))
   :ORDER2 (count (filter #(= "2" (:ORDER_CATEGORY %)) maps))})
=> ({:MONTH "01", :ORDER1 2, :ORDER2 1} {:MONTH "02", :ORDER1 1, :ORDER2 0})

请注意，通常，此解决方案更有利：

(reduce (fn [acc {:keys [MONTH ORDER_CATEGORY]}]
          (update-in acc [MONTH ORDER_CATEGORY] 
                     (fnil inc 0)))
        {} CON)
=> {"02" {"1" 1}, "01" {"2" 1, "1" 2}}

它返回一个month->order-category->count映射，该映射独立于输入集中存在的订单类别和月份的种类和类型。

例如

(reduce (fn [acc {:keys [MONTH ORDER_CATEGORY]}]
          (update-in acc [MONTH ORDER_CATEGORY]
                     (fnil inc 0)))
        {} (conj CON
                 {:MONTH "01" :ORDER_CATEGORY "foo"}
                 {:MONTH "02" :ORDER_CATEGORY "foo"}
                 {:MONTH "02" :ORDER_CATEGORY "bar"}
                 {:MONTH "02" :ORDER_CATEGORY "1"}))
=> {"02" {"bar" 1, "foo" 1, "1" 2}, "01" {"foo" 1, "2" 1, "1" 2}}

但是，您应该知道，如果ORDER_CATEGORY的计数为0，则结果中没有任何关联的值。