如何构造一个js对象并用js_of_ocaml调用它的方法？

Question

我尝试使用js_of_ocaml构建应用程序。 假设我在javascript中有以下代码：

function MyFunction(){ this.name = "a" }
MyFunction.prototype.setName = function(arg){ this.name = arg }

如何在OCaml / js_of_caml中编写一个与下面的js代码具有相同效果的代码？

val myInstance = new MyFunction();
myInstance.setName("Joe");

我试着写下这样的东西：

let onload _ =
  let myInstance = Js.Unsafe.new_obj (Js.Unsafe.variable "MyFunction") [||] in
  Js.Unsafe.call (Js.Unsafe.variable "MyFunction.prototype.setName") myIntance [|Js.Unsafe.inject "Joe"|];
  Js._false ;;
let _ = Html.window##onload <- Html.handler onload;

调用构造函数，但我有错误，因此它似乎不是正确的方法。 我也尝试过Js.Unsafe.meth_call函数，但它并不是更好。

任何帮助，将不胜感激。

Answer 1

您的不安全版本应该可以使用

let onload _ =
  let myInstance = Js.Unsafe.new_obj (Js.Unsafe.variable "MyFunction") [||] in
  Js.Unsafe.meth_call myInstance "setName" [|Js.Unsafe.inject (Js.string "Joe")|];
  Js._false ;;
 let _ = Dom_html.window##onload <- Dom_html.handler onload;

它生成

function _A_(_a_){new MyFunction().setName("Joe");return _M_}

一个更安全（打字）的版本

class type myFun = object
  method setName : Js.js_string Js.t -> unit Js.meth
end
let myFun : myFun Js.t Js.constr =
  Js.Unsafe.global##_MyFunction (* same as Js.Unsafe.variable "MyFunction" *)

let onload _ =
  let myInstance = jsnew myFun () in
  myInstance##setName(Js.string "Joe");
  Js._false ;;
let _ = Dom_html.window##onload <- Dom_html.handler onload;

它生成以下JavaScript

var _Q_=_d_.MyFunction;
function _A_(_a_){new _Q_().setName("Joe");return _M_}
_d_.onload=  .... _A_(..)