在Ratpack Groovy中解析json

Question

我在Groovy控制台中启动了一个小型的ratpack应用程序，但我无法从文档中找到如何获取已在请求中发送的json数据。

@Grab("io.ratpack:ratpack-groovy:0.9.4")
import static ratpack.groovy.Groovy.*
import groovy.json.JsonSlurper

ratpack {
  handlers {
    get {
      def slurper = new JsonSlurper()
      def result = slurper.parseText('{"person":{"name":"Guillaume","age":33,"pets":["dog","cat"]}}')
      render "Hello world! ${result.person}"
    }
    post("foo") {
      def slurper = new JsonSlurper()
      def result = slurper.parseText("WHAT DO i PUT HERE?")
      render "Hello world! ${result.person}"
    }
  }
}

一个示例请求：

curl -XPOST -H "Content-Type: application/json" -d '{"person":{"name":"Guillaume","age":33,"pets":["dog","cat"]}}' localhost:5050/foo

Answer 1

Ratpack提供了一个称为Parser的概念，允许您将传入的请求主体解析为给定类型。

在您的情况下，您可以使用ratpack-jackson模块将传入的请求主体解析为JsonNode或您自己的类型。 您可以在此处找到更多信息。

以下是使用ratpack-jackson模块提供的解析器的示例：

@Grab("io.ratpack:ratpack-groovy:0.9.12")     
@Grab("io.ratpack:ratpack-jackson:0.9.12")    

import static ratpack.groovy.Groovy.*         
import ratpack.jackson.JacksonModule          
import static ratpack.jackson.Jackson.jsonNode

ratpack {                                     
  bindings {                                  
    add new JacksonModule()                   
  }                                           
  handlers {                                  
    post("foo") {                             
      def postBody = parse jsonNode()
      render "Hello world! ${postBody.person}"
    }                                         
  }                                           
}                 

你的卷曲

curl -XPOST -H "Content-Type: application/json" -d '{"person":{"name":"Guillaume","age":33,"pets":["dog","cat"]}}' localhost:5050/foo

回复为

Hello world! {"name":"Guillaume","age":33,"pets":["dog","cat"]}

我希望这有帮助！

Answer 2

之前的答案不再适用。
从版本0.9.19开始，Ratpack返回一个Promise。 此外，它还包括Jackson解析支持。 因此，在撰写本文时，您的示例将如下所示：

context.parse(Jackson.fromJson(Map)).then { data ->
    println data.person
    // do something with person
    context.response.status(201).send()
}

完整文档可在此处获取： https ： //ratpack.io/manual/current/api/ratpack/jackson/Jackson.html#parsing

ps我对该示例所做的一个语义更改是返回201（已创建），因为它是POST。

Answer 3

request.body.text将给出JSON主体的字符串格式

post("foo") {
  def slurper = new JsonSlurper()
  def result = slurper.parseText( request.body.text )
  render "Hello world! ${result.person}"
}