为什么不接受$$类型的char

Question

我不明白为什么这不起作用。 我用$$尝试了usind int值，它工作得很好，但是除非有另一种方式，我希望它与chars一起使用。 这是我的.l文件：

%{
#include "y.tab.h"
%}
%option noyywrap
%option yylineno
%%
DEFINE return DEFINETAG;
BEGIN return BEGINTAG;
END return ENDTAG;
[A-Z]+[0-9] {strcpy(yylval.buf,yytext); return AUT;}
[a-z_]+(0|[1-9][0-9]*)? {strcpy(yylval.buf, yytext); return EST;}
(\{[^}*]*\})* {strcpy(yylval.buf, yytext); return CODC;}
[->;] return yytext[0];
[ \t\n] ;
. yyerror("Caracter Inválido");
%%

这是我的.y文件：

%{
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
extern int yylineno;
int r; int c;
%}
%union {char buf[50]; int val;}
%start gda
%token<buf> BEGINTAG ENDTAG DEFINETAG AUT EST CODC
%type<buf> desta daute dest dtraa dautt dtra
%%
gda  : gda desta dtraa devea {char ma[r][c]; printf("%d, %d\n",r,c);}
     |
     ;
desta: DEFINETAG BEGINTAG daute ENDTAG {$$=$3;}
     ;
daute: daute AUT dest {$$=$3;}
     |
     ;
dest : dest EST {r=r+1;$$=$2;}
     | EST {r=r+1;$$=$1;}
     ;
dtraa: DEFINETAG BEGINTAG dautt ENDTAG 
     ;
dautt: dautt AUT dtra 
     |
     ;    
dtra : dtra EST '-''>' EST {c=c+1;}
     | EST '-''>' EST {c=c+1;}
     ;
devea: devea AUT {printf("void %s(){\n",$2);} BEGINTAG deve ENDTAG {printf("}\n");}
     | AUT {printf("void %s(){\n",$1);} BEGINTAG deve ENDTAG {printf("}\n");}
     ;
deve : deve est CODC
     | 
     ;
est  : EST '-''>' EST {printf("if(estado==%s)estado=%s;\n",$1,$4);}
     |
     ;
%%
int main(){
yyparse();
return 0;
}
int yyerror(char *s){fprintf(stderr, "ERRO(%d):%s\n", yylineno,s); return 0;}

这是我的错误清单：

gda2.y: In function ‘yyparse’:
gda2.y:16:12: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’
gda2.y:18:12: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’
gda2.y:21:18: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’
gda2.y:22:18: error: incompatible types when assigning to type ‘char[50]’ from type ‘char *’

Answer 1

在C语言中，分配给数组是不合法的。 例如，您不能执行以下操作：

 char c[50];
 c = "abc";  /* ILLEGAL */

将数组放入并union不会解决问题：

 union {
   char c[50];
   int  i;
 } u;
 u.c = "abc";  /* ILLEGAL */

但是，奇怪的是，即使它们包含数组，也可以将一个结构分配给另一个：

 struct FiftyChars {
   char c[50];
 };

 struct FiftyChars a,b;
 strncpy(a.c, "abc", 49);
 b = a;                /* ¡LEGAL! */

bison和yacc不允许您避开C的规则。由于$$ = $2实际上被转换为：

yylval.buf = yystack[top - 2].buf;

buf所指的任何内容都需要允许直接分配。 因此它不能是数组。 但它可以是一个struct ，其唯一构件是一个数组。 这意味着您可以将%union声明更改为

%union {struct {char c[50];} buf; int val;}

然后在整个代码中进行适当的更改（例如在flex输入文件buf.c buf更改为buf.c ，在printf的文件buf.c $n更改$nc ）。

另外，您可以通过仅使用strncpy复制字符串并编写来避免此问题

strncpy($$, $1, 49);

代替

$$ = $1;

在你的行动中。 尽管我不知道yacc的每个实现是否都将默认操作（ $$ = $1 ）作为联合副本（会很好）还是作为类型副本（会抛出错误）来处理，但这对bison应该可以正常工作）。

另一方面，您可能会在某个时候问自己50尺寸的来源。 绝对足够大吗？ 您是否检查令牌以确保其长度不超过49个字符？ 您的代码是否可能充满潜在的缓冲区溢出？

一旦开始以这种方式思考，您将发现最好使用指向动态分配的缓冲区的指针来定义联合：

%union {char* buf; int val;}

现在，将一个语义值的并集中的buf分配给另一语义值中的buf并没有问题，您可以在flex文件中使用strdup初始化buf字段。 但是，您现在还有另一个问题，那就是您需要free所有这些动态分配的名称，否则将面临内存泄漏。

如果您要做的只是构建一个小型的单通道编译器，那么虽然很丑陋，但仍然有可能遇到内存泄漏。 毕竟，当程序终止时，无需执行任何操作即可释放其所有内存。 那是传统的风格，尽管我怀疑绝大多数阅读此答案的程序员都会对这一建议感到愤怒。

不幸的是，它并不是那么容易修复。 语义值从一个堆栈位置传递到另一个堆栈位置，没有一种简单的方法来知道给定字符串中有多少个指针，或者何时不再需要该字符串。 如果您使用C ++作为基本语言而不是C，则可以使用std::string ，它可以处理所有这些问题以及分配适当的大缓冲区，但这样做的代价是需要做很多不必要的字符串复制。 或者，您可以使用指向std :: string的共享指针，这将再次为您做引用计数，但又要花费一定的运行时间。

一段时间以来，我的解决方案一直是在词法分析器中维护“ interned”字符串的字典（即唯一字符串），并让词法分析器返回指向（ const ）唯一字符串的指针。 这需要为每个字符串令牌进行哈希表查找，但是可以有效地处理垃圾回收问题。 在解析结束时，可以简单地删除词法分析器及其关联的唯一字符串哈希表。 （当然，如果一个字符串的生存期比词法分析器更长，则需要将其复制。但是在许多情况下，这不是问题。）