简单的应用函数示例

Question

我正在读“了解你一本哈斯克尔”一书。 我很难理解这个应用程序的编码器代码：

(*) <$> (+3) <*> (*2) $ 2

这归结为：（3 + 2）*（2 * 2）= 20

我不遵循如何。 我可以将上面的内容扩展为不那么优雅但更明确的新手理解版本：

((fmap (*) (+3)) <*> (*2)) 2

我理解<*>运算符的基础知识。 这很有道理：

class (Functor f) => Applicative f where
    pure :: a -> f a
    (<*>) :: f (a -> b) -> f a -> f b

但我不知道命令是如何工作的？ 有小费吗？

Answer 1

处理这类问题的一种方法是使用替代。 在这种情况下，使用运算符(<*>)或函数，获取其实现并将其插入到相关代码中。

在的情况下(*) <$> (+3) <*> (*2) $ 2您所使用的((->) a)的实例Applicative中发现的Applicative在基本模块 ，可以发现实例通过单击右侧的源链接并搜索“（ - >”：

instance Applicative ((->) a) where
    pure = const
    (<*>) f g x = f x (g x)

使用(<*>)的定义，我们可以继续替换：

((fmap (*) (+3)) <*> (*2)) 2 == (fmap (*) (+3)) 2 ((*2) 2)
== (fmap (*) (+3)) 2 4

好了，我们需要((->) a)的Functor实例。 您可以通过为黑线鳕信息发现这个Functor ， 在这里点击右边的源链接，并搜索“（ - >”中找到：

instance Functor ((->) r) where
    fmap = (.)

现在继续代替：

(fmap (*) (+3)) 2 4 == ((*) . (+3)) 2 4
== (*) ((+3) 2) 4
== (*) 5 4
== 20

一个更具象征意义的appraoch

许多人在用象征性思考这些问题时会报告更好的长期成功。 而不是通过问题提供2值，而是将焦点放在(*) <$> (+3) <*> (*2)并且仅在末尾应用2。

(*) <$> (+3) <*> (*2)
== ((*) . (+3)) <*> (*2)
== (\x -> ((*) . (+3)) x ((*2) x))
== (\x -> ((*) . (+3)) x (x * 2))
== (\x -> (*) (x + 3) (x * 2))
== (\x -> (x + 3) * (x * 2))
== (\x -> 2 * x * x + 6 * x)

好的，现在插入2 for x

2 * 2 * 2 + 6 * 2
8 + 12
20