需要帮助来改善我的VBA循环

Question

我有一个由两列组成的Excel工作表，其中一列填充字符串，另一列为空。 我想使用VBA根据另一列中相邻字符串的值来分配空列中单元格的值。

我有以下代码：

Dim regexAdmin As Object 
Set regexAdmin = CreateObject("VBScript.RegExp") 
regexAdmin.IgnoreCase = True
regexAdmin.Pattern = "Admin" 

Dim i As Integer
For i = 1 To 10 'let's say there is 10 rows
    Dim j As Integer
    For j = 1 To 2
        If regexAdmin.test(Cells(i, j).Value) Then
            Cells(i, j + 1).Value = "Exploitation"
        End If
    Next j
Next i

问题在于，当使用此循环处理大量数据时，它花费的时间太长，无法正常工作，并且在大多数情况下，它只会使Excel崩溃。

有人知道更好的方法吗？

Answer 1

您有一个不必要的循环，在这里您还要测试刚刚完成的列（j）。 下降速度应提高10-50％

Dim regexAdmin As Object 
Set regexAdmin = CreateObject("VBScript.RegExp") 
regexAdmin.IgnoreCase = True
regexAdmin.Pattern = "Admin" 

Dim i As Integer
For i = 1 To 10 'let's say there is 10 rows
        If regexAdmin.test(Cells(i, 1).Value) Then
            Cells(i, 1).offset(0,1).Value = "Exploitation"
        End If
Next i

如果正则表达式模式确实只是“ Admin”，那么您也可以为此使用工作表公式，而不用编写宏。 您将在文本列旁边放置的公式（假设您的字符串/数字为A）将为：

=IF(NOT(ISERR(FIND("Admin",A1))),"Exploitation","")

通常，如果可以使用公式完成此操作，则最好这样做。 它更易于维护。

Answer 2

尝试这个：

Public Sub ProcessUsers()

    Dim regexAdmin As Object
    Set regexAdmin = CreateObject("VBScript.RegExp")
    regexAdmin.IgnoreCase = True
    regexAdmin.Pattern = "Admin"

    Dim r As Range, N As Integer, i As Integer
    Set r = Range("A1") '1st row is headers
    N = CountRows(r) - 1 'Count data rows

    Dim inputs() As Variant, outputs() As Variant
    inputs = r.Offset(1, 0).Resize(N, 1) ' Get all rows and 1 columns
    ReDim outputs(1 To N, 1 To 1)

    For i = 1 To N
        If regexAdmin.test(inputs(i, 1)) Then
            outputs(i, 1) = "Exploitation"
        End If
    Next i

    'Output values
    r.Offset(1, 1).Resize(N, 1).Value = outputs
End Sub


Public Function CountRows(ByRef r As Range) As Long
    If IsEmpty(r) Then
        CountRows = 0
    ElseIf IsEmpty(r.Offset(1, 0)) Then
        CountRows = 1
    Else
        CountRows = r.Worksheet.Range(r, r.End(xlDown)).Rows.Count
    End If
End Function