Windows批处理脚本：ENABLEDELAYEDEXPANSION + For循环无法按预期工作

Question

我不确定如何使以下代码正常工作。 该循环不会返回所有假定的文件，并且%%~FI仅在FOR循环开始时扩展。 到最后一条命令执行时， "%%~FI"产生文字字符串，而不是扩展为所需的文件名：

SETLOCAL ENABLEDELAYEDEXPANSION
FOR %%I IN (*.foo *.bar) DO (
    SET OFileBase=%%~DPNI
    ECHO "%%~FI" REM Expands correctly at this point
    :WhileLoop2
    IF EXIST "!OFileBase!.baz" (
        SET /A SuffixIndex += 1
        SET OFileBase=%%~DPNI [!SuffixIndex!]
        GOTO WhileLoop2
    )
    ECHO "%%~FI" REM Expands no more, now a literal string?!
    fooparser.exe --input "%%~FI" - | bazmaker.exe - "!OFileBase!.baz"
)
ENDLOCAL

我究竟做错了什么？

Answer 1

SETLOCAL ENABLEDELAYEDEXPANSION
FOR %%I IN (*.foo *.bar) DO (
    SET OFileBase=%%~DPNI
    ECHO "%%~FI" REM Expands correctly at this point
    call :WhileLoop2 "%%~DPNI"
    ECHO "%%~FI" REM Expands no more, now a literal string?!
    fooparser.exe --input "%%~FI" - | bazmaker.exe - "!OFileBase!.baz"
)
ENDLOCAL
goto :eof

:WhileLoop2
IF EXIST "!OFileBase!.baz" (
 SET /A SuffixIndex += 1
 SET OFileBase=%~1 [!SuffixIndex!]
 GOTO WhileLoop2
)
goto :eof

始终很难处理一批中的孤立部分-尤其是显然已被进一步杀菌的部分。

您的问题是试图在block语句（带括号的一系列语句）中使用标签。 这不是一个好主意-混淆FOR并终止循环。

由于您正在内部循环中使用元变量%%I ，因此请将它作为带引号的参数（以防%%I包含分隔符）传递给子例程，然后以%~1访问子例程中的值，从而删除引号。