VBA IF然后Vlookup多个工作表

Question

我正在尝试使用VLOOKUP函数从另一个文件中检索数据，但这仅取决于3栏（C）中是否出现了这2个数据项

“ PO材料”或“ PO人工”

Sub MakeFormulas()

Dim SourceLastRow As Long
Dim OutputLastRow As Long
Dim sourceSheet As Worksheet
Dim outputSheet As Worksheet
Dim X As Long

'What are the names of our worksheets?
Set sourceSheet = Worksheets("Sheet1")
Set outputSheet = Worksheets("Sheet2")


'Determine last row of source
With sourceSheet
    SourceLastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
End With

With outputSheet

    'Determine last row in col C
    OutputLastRow = .Cells(.Rows.Count, "E").End(xlUp).Row

    For X = 5 To OutputLastRow
        If InStr(1, .Range("C" & X), "PO Materials") > 0 Then
            'Apply our formula
        .Range("Q2:Q" & OutputLastRow).Formula = _
            "=VLOOKUP(E2,'" & sourceSheet.Name & "'!$A$2:$B$" & SourceLastRow & ",2,0)"
        End If
    Next
End With

End Sub

代码正在运行； 但是，如果单元格为空或在C列中包含任何值，则给出＃N / A，这意味着它无法识别If语句。 如果该列不包含“ PO物料”或“ PO人工”，则希望跳至该范围内的下一个单元格

在此先感谢您提供的任何帮助。

Answer 1

生成VLOOKUP的代码每次都会将该公式应用于列中的每个单元格。 也就是说，每次你的时间If条件可找到“PO材料”，它将VLOOUKP适用于Q2和E列中的最后一行之间的每一个细胞

我认为这是您想要的：

.Range("Q" & X).Formula = _
    "=VLOOKUP(E" & X & ",'" & sourceSheet.Name & "'!$A$2:$B$" & SourceLastRow & ",2,0)"

另外，也可以在电子表格中完全完成此操作：

=IF(ISERROR(FIND("PO Materials",C6)),"",VLOOKUP(E6,Sheet1!$A$2:$B$6,2,0))

Answer 2

最终代码以供将来参考

Sub MakeFormulas()
Dim SourceLastRow As Long
Dim OutputLastRow As Long
Dim sourceSheet As Worksheet
Dim outputSheet As Worksheet
Dim X As Long

'What are the names of our worksheets?
Set sourceSheet = Worksheets("Sheet1")
Set outputSheet = Worksheets("Sheet2")


'Determine last row of source
With sourceSheet
SourceLastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
End With
With outputSheet

'Determine last row in col C
OutputLastRow = .Cells(.Rows.Count, "C").End(xlUp).Row

For X = 2 To OutputLastRow
If InStr(1, .Range("C" & X), "PO Materials") + InStr(1, .Range("C" & X), "PO Labor") > 0 Then
    'Apply our formula
.Range("Q" & X).Formula = _
"=VLOOKUP(E" & X & ",'" & sourceSheet.Name & "'!$A$2:$B$" & SourceLastRow & ",2,0)"
End If
Next
End With
End Sub