批量显示两个文件夹中带有* _ ???? *。*的文件

Question

抱歉，但是我的英语很差！ 我有两个文件夹，其中包含几个文件，如下所示：

D:\Folder1\
START_0101.dat..
START_0105.dat..
START_0109.dat..
..
..
..
START_0250.dat.

D:\Folder2\
rms_20141124_0100.mdb..
rms_20141124_0108.mdb..
rms_20141124_0109.mdb..
..
..
..
rms_20141124_0250.mdb.

我需要一个批处理脚本来显示Folder2中存在文件* 109.mdb和* 250.mdb。 如果存在，则显示一条消息。

Windows 2000

---

我的文件夹1中可以有多个文件，其格式为“ * _ ???????。dat”。 D：\\ Folder1 \\ START_0101.dat .. START_0105.dat .. START_0109.dat ..。。。。* * _ ????。dat

我可以在Folder2中拥有多个文件，其格式为“ * _ ???????。mdb”。 D：\\ Folder2 \\ rms_20141124_0100.mdb .. rms_20141124_0108.mdb .. rms_20141124_0109.mdb ....... * * _ ????。mdb

我需要这样的东西：

如果存在“ d：\\ folder1 * _ ??????? ”，则设置“ found = 1”；如果存在“ d：\\ folder1 * _ ??????? ”，则设置“ found = 2”

如果“％1％” EQU“％2％”（回声文件％found％存在），否则（回声文件不存在）

非常感谢！

Answer 1

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "folder1=d:\folder1"
    set "folder2=d:\folder2"

    for %%a in ("%folder1%\*.dat") do (
        for /f "tokens=2 delims=_" %%b in ("%%~na") do (
            if exist "%folder2%\*_%%b.mdb" (
                echo %%b exists
            ) else (
                echo %%b missing
            )
        )
    )

对于每一个.dat文件夹1的文件，检索到文件的引用for可替换参数%%a ，从它，得到的文件名（ %%~na ），使用下划线作为分隔符标记化，并检索所述第二令牌。 显示文件夹2中是否存在具有相同标记的.mdb文件。

编辑以适应folder2中的多个子文件夹

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "folder1=d:\folder1"
    set "folder2=d:\folder2"

    for %%a in ("%folder1%\*.dat") do (
        for /f "tokens=2 delims=_" %%b in ("%%~na") do (

            set "match="
            for /r "%folder2%" %%c in ("*_%%b.mdb") do  if not defined match (
                set "match=1"
                echo %%~nxa located as %%c
            )

            if not defined match (
                echo %%b missing
            )
        )
    )