一个简单的C ++程序示例的BNF语法

Question

所以我正在尝试为一个简单的C ++程序编写语法。

这就是现在的语法：

PDefs. Program ::= [Def] ;
terminator Def "" ;
comment "//" ;
comment "/*" "*/" ;
comment "#" ;
DFun. Def ::= Type Id "(" [Arg] ")" "{" [Stm] "}" ;
separator Arg "," ;
terminator Stm "" ;
ADecl. Arg ::= Type Id ;
SExp. Stm ::= Exp ";" ;
SDecl. Stm ::= Type Id ";" ;
SDecls. Stm ::= Type Id "," [Id] ";" ;
SInit. Stm ::= Type Id "=" Exp ";" ;
SReturn. Stm ::= "return" Exp ";" ;
SWhile. Stm ::= "while" "(" Exp ")" Stm ;
SBlock. Stm ::= "{" [Stm] "}" ;
SIfElse. Stm ::= "if" "(" Exp ")" Stm "else" Stm ;


EInt. Exp15 ::= Integer ;
EDouble. Exp15 ::= Double ;
ETrue. Exp15 ::= "true" ;
EFalse. Exp15 ::= "false" ;
EId. Exp15 ::= Id ;
EApp. Exp15 ::= Id "(" [Exp] ")" ;
EPIncr. Exp14 ::= Exp15 "++" ;
EPDecr. Exp14 ::= Exp15 "--" ;
EIncr. Exp13 ::= "++" Exp14 ;
EDecr. Exp13 ::= "--" Exp14 ;
ETimes. Exp12 ::= Exp12 "*" Exp13 ;
EDiv. Exp12 ::= Exp12 "/" Exp13 ;
EPlus. Exp11 ::= Exp11 "+" Exp12 ;
EMinus. Exp11 ::= Exp11 "-" Exp12 ;
ELt. Exp9 ::= Exp9 "<" Exp10 ;
EGt. Exp9 ::= Exp9 ">" Exp10 ;
ELtEq. Exp9 ::= Exp9 "<=" Exp10 ;
EGtWq. Exp9 ::= Exp9 ">=" Exp10 ;
EEq. Exp8 ::= Exp8 "==" Exp9 ;
ENEq. Exp8 ::= Exp8 "!=" Exp9 ;
EAnd. Exp4 ::= Exp4 "&&" Exp5 ;
EOr. Exp3 ::= Exp3 "||" Exp4 ;
EAss. Exp2 ::= Exp3 "=" Exp2 ;

coercions Exp 15 ;
separator Exp "," ;
separator Id "," ;

Tbool. Type ::= "bool" ;
Tdouble. Type ::= "double" ;
Tint. Type ::= "int" ;
Tvoid. Type ::= "void" ;

token Id (letter (letter | digit | '_')*) ;

这是需要解析的简单c ++程序

// a small C++ program
#include <iostream>

int main()
{
    std::cout << "Hello, world!" << std::endl;
    return 0;
}

所以当我尝试解析它时，我在第6行中得到了错误，这意味着std :: cout行。 由于我是bnf的新手，所以我不知道如何“思考”解决此问题。 如果有人可以举一个例子说明如何解决这种情况，那就太好了！

谢谢！

Answer 1

失败的行无法解析，因为您缺少一些规则：

1. 您需要一个规则来解析合格的ID 。
   合格的ID是一种特殊的标识符，可以（出于您的目的）在与（不合格的）标识符相同的情况下使用。
   std::cout和std::endl是合格的ID，针对它们的（简化）规则可能看起来像这样：

    <qualified_id> ::= <nested_name_specifier> <unqualified_id> <nested_name_specifier> ::= <namespace_name> "::" <nested_name_specifier>? 

   （出于您的目的），其中<unqualified_id>和<namespace_name>可以被视为标识符。

2. 您需要使用<<操作符解析表达式的规则。
   这种附加类型的表达式的（简化）规则如下所示：

    <shift_left_expression> ::= <other_expression> <shift_left_expression> ::= <shift_left_expression> "<<" <other_expression> 

   其中（出于您的目的） <other_expression>代表任何其他类型的表达式。

3. 您需要一个规则来解析字符串文字 。
   字符串文字是一种文字，可以（出于您的目的）用作表达式的一部分（例如标识符）。
   "Hello, world!" 是一个字符串文字，它们的（简化）规则可能类似于以下内容：

    <string_literal> ::= "\\"" <s_char_sequence>? "\\"" <s_char_sequence> ::= <s_char> <s_char_sequence> ::= <s_char_sequence> <s_char> 

   其中<s_char>是您要在字符串文字中允许的任何字符（为简单起见 ，请勿在其中包含"字符。）。