SAS：如何使用RETAIN语句在DATA步骤中创建求和变量，相当于PROC PRINT中的SUM语句输出

Question

在SAS中，我正在尝试创建一个另一个变量的变量。 在这种情况下，我试图创建两个变量： Total_All_Ages ，它是2013年美国人口POPESTIMATE2013的总和，以及Total_18Plus ，它是2013年美国18岁以上人口POPEST18PLUS2013 。

我希望这些变量的输出看起来好像我在proc print下使用了sum语句（其中sum总和出现在新行的变量列的底部）。 但是，我不想使用print程序。 相反，我想仅使用data步骤创建输出。

我需要这样做的方法是使用retain （和input ）语句。

我的代码如下：

data _NULL_;
retain Total_All_Ages Total_18Plus;
infile RAWfoldr DLM=',' firstobs=3 obs=53;
informat STATE $2. NAME $20.;
input SUMLEV REGION $ DIVISION STATE $ NAME $ POPESTIMATE2013 POPEST18PLUS2013 PCNT_POPEST18PLUS;
    Total_All_Ages = sum(Total_All_Ages, POPESTIMATE2013);
    Total_18Plus = sum(Total_18Plus, POPEST18PLUS2013);
keep STATE NAME POPESTIMATE2013 POPEST18PLUS2013 Total_All_Ages Total_18Plus;
format POPESTIMATE2013 comma11. POPEST18PLUS2013 comma11.;
file print notitles;
if _n_=1 then put '=== U.S. Resident Population Estimates for All Ages and ===
                  Ages 18 or Older by State (in Alphabetical Order), 2013';
if _n_=1 then put ' ';
if _n_=1 then put @5 'FIPS Code' @16 'State Name' @40 'All Ages' @55 'Ages 18 or Older';
if _n_=1 then put ' ';
put @5 STATE @16 NAME @40 POPESTIMATE2013 @55 POPEST18PLUS2013;
run;

您可以在我的input语句中看到，我创建了我提到的两个变量。 我也在retain声明中提到它们。 但是，我不知道如何以我指定的方式使它们出现在我的输出中。

我希望它们在输出的底部显示为Total行，如下所示：

                                                        POPESTIMATE2013  POPEST18PLUS2013
                                                        112312234        1234123412341234
                                                        23413412341234   213412341234



                       ============                      ============     ============
                       Total                             23423423429      242234545345 

有没有办法将这些变量放在输出最底部的新行上（有点像我如何使用if _n_=1代码放置变量标签）？

如果我需要更好地解释自己，请告诉我。 我很感激任何帮助。 谢谢。

Answer 1

如果我理解你的问题，你几乎就在那里。

首先，将end=eof添加到infile语句中。 这会初始化一个等于0的变量“eof”，但只有当SAS读取最后一行数据时才会等于1。 这也适用于set语句。

接下来，添加此do块，当sas位于文件的最后一行时执行：

  if eof then do;
    put @5 9*'=' @40 11*'=' @55 11*'=';
    put @5 'Total' @40 Total_All_Ages comma11. @55 Total_18Plus comma11.;
  end;

在这里，您使用put语句打印格式（重复='标志）和总计。 完整代码如下：

data _NULL_;
  retain Total_All_Ages Total_18Plus;
  infile RAWfoldr DLM=',' firstobs=3 obs=53 end=eof;
  informat STATE $2. NAME $20.;
  input SUMLEV REGION $ DIVISION STATE $ NAME $ POPESTIMATE2013 POPEST18PLUS2013 PCNT_POPEST18PLUS;
    Total_All_Ages = sum(Total_All_Ages, POPESTIMATE2013);
    Total_18Plus = sum(Total_18Plus, POPEST18PLUS2013);
  keep STATE NAME POPESTIMATE2013 POPEST18PLUS2013 Total_All_Ages Total_18Plus;
  format POPESTIMATE2013 comma11. POPEST18PLUS2013 comma11.;
  file print notitles;
  if _n_=1 then put '=== U.S. Resident Population Estimates for All Ages and ===
                    Ages 18 or Older by State (in Alphabetical Order), 2013';
  if _n_=1 then put ' ';
  if _n_=1 then put @5 'FIPS Code' @16 'State Name' @40 'All Ages' @55 'Ages 18 or Older';
  if _n_=1 then put ' ';
  put @5 STATE @16 NAME @40 POPESTIMATE2013 comma11. @55 POPEST18PLUS2013 comma11.;
  if eof then do;
    put @5 9*'=' @40 11*'=' @55 11*'=';
    put @5 'Total' @40 Total_All_Ages comma11. @55 Total_18Plus comma11.;
  end;
run;

关于代码的最后一点注意事项：您可以通过在put语句中指定格式后跟“-r”来右对齐数字，例如：

  put @5 STATE @16 NAME @40 POPESTIMATE2013 comma11.-r @55 POPEST18PLUS2013 comma11.-r;

这将覆盖您拥有的任何格式语句。