跨多个工作表的VBA Vlookup

Question

因此，我有两个列表，每个列表在不同的工作表中。 我正在检查工作表B中的值是否也在工作表A中。为此，我使用VLookup，问题似乎出在range语句上，因为此范围似乎是“空”的。

我的VBA尝试是这样的，

Dim lookupVal As String
Dim myString As String

For i = 1 to N
    lookupVal = Sheets("b").Cells(1 + i, 2)
    myString = Application.WorksheetFunction.VLookup(lookupVal, Sheets("a").range(Sheets("a").Cells(9,3), Sheets("a").Cells(N+8, 3)), 1, False)
    If IsEmpty(myString) Then
        Sheets("b").Cells(1+i, 3) = ""
    Else
        Sheets("b").Cells(1+i, 3) = myString
    End if

Next i

我收到“运行时1004：应用程序定义或对象定义的错误”。 任何帮助表示赞赏。

Answer 1

将您的代码更改为以下内容。

If IsEmpty(myString)是错误的方法。 在#N/A情况下，该语句仍然是正确的。

这是您要尝试的吗？

Sub Sample()
    Dim lookupVal As String
    Dim myString As Variant
    Dim rng As Range

    '~~> Change this whatever you want
    n = 5

    For i = 1 To n
        lookupVal = Sheets("b").Cells(1 + i, 2)

        Set rng = Sheets("a").Range(Sheets("a").Cells(9, 3), Sheets("a").Cells(n + 8, 3))

        myString = Application.Evaluate("=VLOOKUP(" & lookupVal & "," & "a!" & rng.Address & ",1,0)")

        Select Case CVErr(myString)
            Case CVErr(xlErrName), CVErr(xlErrNA), CVErr(xlErrRef), CVErr(xlErrValue)
            Case Else: Sheets("b").Cells(1 + i, 3) = myString
        End Select
    Next i
End Sub

Answer 2

您的代码中有两个问题：

1. 对于worksheetfunction.vlookup ，搜索范围不能是可变的。 因此，解决此问题的方法是使用其他变量将其永久化

2. 如果worksheetfunction.vlookup找不到搜索值，则会出现错误，在这种情况下，您需要对错误处理使用其他操作

3. 由于单元格的格式（lookup范围和lookup值）可以不同， lookupVal必须将lookupVal声明as Range ，但是在代码单元格中，值始终会转换为字符串类型，如果将其转换为字符串类型，则将无法找到数字串

4. 由于与“ 3”中所述的相同原因，还必须将myString声明as Variant 。 例如，单元格的类型可以为double ，但是您的代码会将其转换为string

因此，您的更新代码如下，可以正常工作

Sub test()
Dim lookupVal As Range, myString As Variant, Rng$, n&
n = Sheets("b").[B:B].Cells.Find("*", , , , xlByRows, xlPrevious).Row
On Error Resume Next
For i = 1 To n
    Set lookupVal = Sheets("b").Cells(1 + i, 2)
    Rng = Range(Cells(9, 3), Cells(n + 8, 3)).Address
    myString = WorksheetFunction.VLookup(lookupVal, Sheets("a").Range(Rng), 1, False)
    If Err.Number > 0 Then
        Sheets("b").Cells(1 + i, 3) = ""
        Err.Clear
    Else
        Sheets("b").Cells(1 + i, 3) = myString
    End If
Next i
End Sub

---

下面的替代方法

Sub test()
Dim cl As Range, Dic As Object
Set Dic = CreateObject("Scripting.Dictionary"): Dic.Comparemode = vbTextCompare
With Sheets("a")
    For Each cl In .Range("C9:C" & .Cells(Rows.Count, "C").End(xlUp).Row)
        If Not Dic.exists(cl.Value) Then Dic.Add cl.Value, cl.Row
    Next cl
End With
With Sheets("b")
    For Each cl In .Range("B2:B" & .Cells(Rows.Count, "B").End(xlUp).Row)
        If Dic.exists(cl.Value) Then cl.Offset(, 1).Value = cl.Value
    Next cl
End With
Set Dic = Nothing
End Sub