根据主题行转发电子邮件

Question

我正在尝试将电子邮件从我公司的 Outlook 转发到我们公司外部的电子邮件帐户。 我被允许这样做。

我想转发主题行中包含“Excel Friday”的任何电子邮件。

Private WithEvents Items As Outlook.Items
Private Sub Application_Startup()
    Dim olApp As Outlook.Application
    Dim objNS As Outlook.NameSpace
    Set olApp = Outlook.Application
    Set objNS = olApp.GetNamespace("MAPI")
    ' default local Inbox
    Set Items = objNS.GetDefaultFolder(olFolderInbox).Items
End Sub
 
Private Sub Items_ItemAdd(ByVal Item As Object)
    On Error GoTo ErrorHandler
    Dim Msg As Outlook.MailItem
    If TypeName(Item) = "MailItem" Then
        Set Msg = Item
        If Msg.Subject = "Excel Friday" Then
            Dim myMail As Outlook.MailItem
            Set myMail = Msg.Reply
            myMail.To = "xxxxxx@fakemail.com"
            myMail.Display
        End If
    End If
ProgramExit:
    Exit Sub
ErrorHandler:
    MsgBox Err.Number & " - " & Err.Description
    Resume ProgramExit
End Sub

Answer 1

我想将主题行中包含“Excel Friday”的任何电子邮件转发到另一个电子邮件地址。

但是在代码中，您检查主题行是否完全匹配：

If Msg.Subject = "Excel Friday" Then

相反，您需要查找子字符串。 要查找字符串中子字符串的位置，请使用Instr函数。

If Instr(Msg.Subject, "Excel Friday") Then

我还注意到您使用了 Reply 方法：

Set myMail = Msg.Reply 

请改用Forward方法：

Set myMail = Msg.Forward

然后使用发送方法。

 myMail.Recipients.Add "Eugene Astafiev" 

 myMail.Send 

请注意，该代码基于ItemAdd事件处理程序。 一次将大量项目（超过 16 个）添加到文件夹时，不会触发此事件。

Answer 2

您可以使用运行脚本规则执行此操作

Sub ChangeSubjectForward(Item As Outlook.MailItem)
    Item.Subject = "Test"
 Item.Save

Set olForward = Item.Forward
olForward.Recipients.Add "Jasonfish11@domain.com"

olForward.Send

End Sub

如果是 vba，您可以随时对文件夹中的所有邮件运行。

粘贴到 ThisOutlookSession 并运行

Sub ChangeSubjectThenSend()
Dim olApp As Outlook.Application
Dim aItem As Object

Set olApp = CreateObject("Outlook.Application")
Set mail = olApp.ActiveExplorer.CurrentFolder

For Each aItem In mail.Items
      aItem.Subject = "New Subject"
    aItem.Save

    Set olForward = aItem.Forward
    olForward.Recipients.Add "Jasonfish11@domain.com"
    olForward.Send

Next aItem
End Sub

源链接