如何在Excel VBA中选择完整范围

Question

当我调试excel-vba程序时，我知道我的数据范围未完全选择。

下图显示了我的数据模型和问题。

我使用此代码选择了整个范围。 但这不能正常工作。

Dim rngTemp As Range
Set rngTemp = Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious)
With rngTemp

请通过提供上图所示的选择整个范围的代码来帮助我。

Answer 1

在您的代码中，您正在按xlByRows搜索。 因此，您将获得最后一个单元格的地址，该单元格的数据为G7 。

根据我的评论，这是您要尝试的吗？

Sub Sample()
    Dim lastrow As Long, lastcol As Long
    Dim rng As Range

    With Sheets("Sheet1") '<~~ Change this to the relevant sheet
        If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
            lastrow = .Cells.Find(What:="*", _
                          After:=.Range("A1"), _
                          Lookat:=xlPart, _
                          LookIn:=xlFormulas, _
                          SearchOrder:=xlByRows, _
                          SearchDirection:=xlPrevious, _
                          MatchCase:=False).Row
            lastcol = .Cells.Find(What:="*", _
                          After:=.Range("A1"), _
                          Lookat:=xlPart, _
                          LookIn:=xlFormulas, _
                          SearchOrder:=xlByColumns, _
                          SearchDirection:=xlPrevious, _
                          MatchCase:=False).Column
        Else
            lastrow = 1: lastcol = 1
        End If

        Set rng = .Range("A1:" & _
                         Split(.Cells(, lastcol).Address, "$")(1) & _
                         lastrow)

        MsgBox rng.Address
    End With
End Sub

Answer 2

请注意，在某些情况下以下方法不可靠。 我将在这里留下这个答案作为一个不好的例子。 有关详细信息，请参阅此链接中的 @SiddharthRout的解释。

我将使用以下代码查找已用范围，而不是在单元格值中查找“ *”：

Sub SelectRange()
    Dim LastRow As Long
    Dim LastColumn As Long
    Dim aWB As Workbook
    Dim aWS As Worksheet

    Set aWB = ActiveWorkbook
    Set aWS = aWB.ActiveSheet '<-You can change sheet name like aWB.sheets("SheetName")

    With aWS.UsedRange
        LastRow = .Rows(.Rows.Count).Row
        LastColumn = .Columns(.Columns.Count).Column
    End With

    aWS.Range(Cells(1, 1), Cells(LastRow, LastColumn)).Select '<---Cells(1, 1) is the starting cell of range)

End Sub