在delphi中测试泛型的类型

Question

我想用一些方法在delphi中编写一个函数，如下所示

procedure Foo<T>;
begin
    if T = String then
    begin
        //Do something
    end;

    if T = Double then
    begin
        //Do something else
    end;
end;

即：我希望能够根据泛型类型做不同的事情

我尝试在System使用TypeInfo ，但这似乎适合于对象而不是泛型类型。

我甚至不确定帕斯卡是否可行

Answer 1

从XE7开始，您可以使用GetTypeKind查找类型类型 ：

case GetTypeKind(T) of
tkUString:
  ....
tkFloat:
  ....
....
end;

当然tkFloat标识所有浮点类型，因此您也可以测试SizeOf(T) = SizeOf(double) 。

较旧版本的Delphi没有GetTypeKind内在函数，您必须使用PTypeInfo(TypeInfo(T)).Kind 。 GetTypeKind的优点是编译器能够对其进行评估并优化掉可以证明不被选中的分支。

所有这些都违背了泛型的目的，人们想知道你的问题是否有更好的解决方案。

Answer 2

TypeInfo应该工作：

type
  TTest = class
    class procedure Foo<T>;
  end;

class procedure TTest.Foo<T>;
begin
  if TypeInfo(T) = TypeInfo(string) then
    Writeln('string')
  else if TypeInfo(T) = TypeInfo(Double) then
    Writeln('Double')
  else
    Writeln(PTypeInfo(TypeInfo(T))^.Name);
end;

procedure Main;
begin
  TTest.Foo<string>;
  TTest.Foo<Double>;
  TTest.Foo<Single>;
end;