在 Neo4j 中基于 Time 属性在节点之间创建有向边

Question

我是 Neo4j 和 Cypher 的新手，在将我们公司的关系数据库转换为基于图形的模型时，我遇到了一个问题，我将不胜感激。

我的模型中有一个类型为 person 的节点，如下所示：

 (:Person {Fname: 'John', catID: 1})
 (:Person {Fname: 'George', catID: 2})
 (:Person {Fname: 'Natalie', catID: 3})

......

我也有这样的基于时间的类别节点：

(:Category {Id: 1, Date: '2015-02-05'})
(:Category {Id: 1, Date: '2015-01-05'})
(:Category {Id: 1, Date: '2015-03-10'})
(:Category {Id: 3, Date: '2014-03-10'})
(:Category {Id: 3, Date: '2015-05-10'})

......

现在我想创建从每个人到其类别中具有最小日期的节点的直接边。 我在上面的例子中的意思是：

 (:Person {Fname: 'John', catID: 1}) --->  (:Category {Id: 1, Date: '2015-01-05'})

 (:Person {Fname: 'Natalie', catID: 3}) --->  (:Category {Id: 3, Date: '2014-03-10'})

之后，我想根据它们的 Date 属性按升序在每个类别中的节点之间创建有向边。 我的意思是：

 (:Category {Id: 1, Date: '2015-01-05'}) ---> (:Category {Id: 1, Date: '2015-02-05'}) ---> (:Category {Id: 1, Date: '2015-03-10'})

 (:Category {Id: 3, Date: '2014-03-10'}) ---> (:Category {Id: 3, Date: '2015-05-10'})

做这些事情所需的密码是什么。 非常感谢提前

Answer 1

以下是您如何完成问题的第一部分，将人们附加到具有最短日期的相应类别节点：

MATCH (p:Person)
MATCH (c:Category)
WHERE p.catID = c.Id
WITH p, c
ORDER BY p.Fname, c.Date
WITH p, HEAD(COLLECT(c)) AS most_recent
MERGE (p)-[:IN_CATEGORY]->(most_recent)

现在我们可以这样做：

MATCH (p:Person)-[:IN_CATEGORY]->(c:Category)
RETURN p.Fname, c.Date

我们得到了结果：

p.Fname   c.Date
John      2015-01-05
Natalie   2014-03-10

要回答您的第二个问题，我们可以这样做：

MATCH (c:Category) WITH c
ORDER BY c.Id, c.Date
WITH c.Id AS id, 
     COLLECT(c) AS categories, 
     COUNT(c) AS count 
UNWIND range(1, count - 1) AS idx
WITH categories[idx - 1] AS from , categories[idx] AS to
CREATE (from)-[:NEXT]->(to);

我从迈克尔的回答中窃取了一些想法。 :) 您现在可以编写这样的查询：

MATCH p = (:Person)-[:IN_CATEGORY]->(:Category)-[:NEXT*]->(:Category)
RETURN p

在此处查看成品： http : //console.neo4j.org/r/999rzg

Answer 2

这几乎很简单:)

创建按时间戳排序的节点链表

MATCH (c:Category)
WITH c order by c.Date
// ordered list
WITH collect(c) as cats 
// index for collection
UNWIND range(1,size(cats)-1) as idx
// subsequent entries
WITH cats[idx-1] as first, cats[idx] as second
CREATE (first)-[:NEXT]->(second)
RETURN count(*);