在Proc SQL Teradata passthrough中使用SAS宏变量

Question

我有一个SQL语句，我希望自动使用SAS EG（9.4）。 以下语句已在Teradata SQL Assistant中进行了测试并正常运行。

select * from TD.DATA where date='2015-06-01'

现在我希望通过proc SQL传递来推送它，并将日期提供给SQL程序，就像这样....

proc sql;
connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
create table MYDATA as 
select * from connection to tera
(
select * from TD.DATA where date='2015-06-01'
);
disconnect from tera;
quit;

上面的代码已经过测试，并产生与前一个SQL语句完全相同的输出。 但是，我真正想要的是做这样的事情：

%let input_date='2015-06-01';
proc sql;
connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
create table MYDATA as 
select * from connection to tera
(
select * from TD.DATA where date=&input_date.
);
disconnect from tera;
quit;

我尝试过不同的报价组合和不同的日期格式....我在这里缺少什么？ 谢谢。

Answer 1

您可以使用%BQUOTE()宏函数来解析单引号内的宏变量。

%let input_date = 2015-06-01;
proc sql;
  connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
  create table MYDATA as 
  select * from connection to tera
  (
   select * from TD.DATA where date = %BQUOTE('&INPUT_DATE')
  );
  disconnect from tera;
quit;

Answer 2

试试这个：

%let input_date=2015-06-01;
proc sql;
connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
create table MYDATA as 
select * from connection to tera
(
select * from TD.DATA where date=%str(%'&input_date%')
);
disconnect from tera;
quit;

Answer 3

与日期201501这样的格式一样，使工作宏变量

%let input_date = 201506;
%let input_date2=input(put(intnx('month',%sysfunc(inputn(&input_date,yymmn6.)),0,'b'),10.),yymmddd10.)
proc sql;
  connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
  create table MYDATA as 
  select * from connection to tera
  (
   select * from TD.DATA where date = %BQUOTE('&INPUT_DATE2')
  );
  disconnect from tera;
quit;