XQuery属性的平均值

Question

我有以下XML输入

<foo>
<bar a=1 b=25/>
<bar a=2 b=30/>
<bar a=1 b=35/>
<bar a=2 b=40/>
<foo>

我需要得到以下结果

<foo>
<bar a=1>average of b = 30</bar>
<bar a=2>average of b = 35</bar>
<foo>

我很难做一个独特的价值。

我有

<foo>
{for $e in doc(XXX.xml)/foo/bar
   return
       <bar a="distinct-values(data($e/@a))">
       {for $c in distinct-values(data($e/@a))
            return avg(data($e/@b))}
       </bar>}
</foo>

我想念什么？

Answer 1

如果您的XQuery处理器支持XQuery 3.0，则可以使用group by结构，该结构正是针对这种用例而设计的，在我看来，它更易于阅读：

<foo>{
  for $el in doc(XXX.xml)/foo/bar
  let $a := $el/@a
  group by $a
  return
         <bar a="{$a}">average of b = {avg($el/@b)}
         </bar>
}
</foo>

它通过a属性将每个bar元素分组，然后计算（并输出） b属性的平均值。

Answer 2

我希望这是您要寻找的。

let $doc :=  <foo>
              <bar a="1" b="25"/>
              <bar a="2" b="30"/>
              <bar a="1" b="35"/>
              <bar a="2" b="40"/>
             </foo>

let $result := <foo>
                {for $a in fn:distinct-values($doc//bar/@a)
                  for $b in avg($doc//bar[@a=$a]/@b)
                   return
                       <bar a="{$a}">
                       averge of b = {$b}
                       </bar>
                }
               </foo>
return $result 

适当的for循环就可以。