如何仅通过在F＃中使用递归来编写此函数？

Question

let rec n_cartesian_product = function
    | [] -> [[]]
    | x :: xs ->
      let rest = n_cartesian_product xs 
      List.concat (List.map (fun i -> List.map (fun rs -> i :: rs) rest) x)

你好！ 我编写了此函数，但是我需要在不使用任何List.*内置函数的情况下编写它。 由于有一个内部函数调用了外部函数，因此我假设必须定义两个相互递归的函数。

定义concat函数似乎很容易：

let rec list_concat ( lst : 'a list list ) : 'a list =
match lst with 
[]    -> []
|x::xs  -> x @ (list_concat xs)

问题是，我陷入了产生concat参数的函数的定义中：

let rec fun_i rest =
    match rest with
    [] -> []
    |x::xs -> fun_rs

and fun_rs =
fun_i :: fun_rs

我似乎无法设计适当的解决方案。 你能帮助我吗？

编辑：例如，鉴于此输入

[["A";"a"];["B";"b"];["C";"c"]]

我想要这个输出：

[["A"; "B"; "C"]; ["A"; "B"; "c"]; ["A"; "b"; "C"]; ["A"; "b"; "c"];
 ["a"; "B"; "C"]; ["a"; "B"; "c"]; ["a"; "b"; "C"]; ["a"; "b"; "c"]]

Answer 1

N-笛卡尔积

要递归定义n个笛卡尔积，最简单的方法就是对原始（非递归）示例中使用的函数进行递归定义：

let rec list_concat lst =
    match lst with 
    |[]    -> []
    |x::xs  -> x @ (list_concat xs)

let rec list_map f lst =
    match lst with
    |[] -> []
    |x::xs -> (f x) :: list_map f xs

let rec n_cartesian_product = 
    function
    | [] -> [[]]
    | x :: xs ->
      let rest = n_cartesian_product xs 
      list_concat (list_map (fun head -> list_map (fun tail -> head :: tail) rest) x)

就用F＃惯用地编写而言，最好使用更通用的函数（例如fold ）进行编写，而不是使用显式递归来制作大量自定义函数。 因此，您可以定义一些其他功能：

let list_collect f = list_concat << list_map f

let rec list_fold f acc lst =
    match lst with
    |[] -> acc
    |hd::tl -> list_fold f (f acc hd) tl

let n_cartesian_product_folder rest first = 
    list_collect (fun head -> list_map (fun tail -> head :: tail) rest) first

然后我们可以简单地重新定义n_cartesian_product ：

let n_cartesian_product2 lst = list_fold (n_cartesian_product_folder) [[]] lst

如果我们使用的是F＃核心库函数（而不是自定义递归实现），则此方法将涉及更多的标准代码，而出错的机会更少。

笛卡尔积 （我将在这里保留这部分，因为它显然很有用）

定义一个函数，该函数采用'a的列表，并生成'b * 'a的列表，其中所有类型'b的事物都是某些提供的元素y 。

/// take a list of 'a and make a list of (y, 'a)
let rec tuplify y lst =
    match lst with
    |[] -> []
    |x::xs -> (y, x) :: (tuplify y xs)

然后定义一个遍历我的两个列表的函数，在第一个列表的当前元素和整个第二个列表上调用tuplify ，并将其与笛卡尔积的递归调用相结合。

/// cartesian product of two lists
let rec cartesianProduct lst1 lst2 =
    match lst1 with
    |[] -> []
    |x::xs -> tuplify x lst2 @ (cartesianProduct xs lst2)