在序言的深列表中汇总原子元素

Question

我是Prolog编程的初学者。 我写了这个程序，用累加器对一个深列表的原子求和。

    deep_sum(Xs, N) :- deep_sum(Xs, 0, N).
    deep_sum([], N, N).
    deep_sum([X|Y], M, N) :- atomic(X), Q is M + X, deep_sum(Y, Q, N).
    deep_sum([X|Y], M, N) :- M is P + Q, deep_sum(X, P, N), deep_sum(Y, Q, N).

为什么会出现“ ERROR：is / 2：参数没有被充分实例化”？

没有累加器也可以正常工作：

    deep_sum([], 0).
    deep_sum([X|Y], S) :- atomic(X), !, deep_sum(Y, Q), S is Q + X.
    deep_sum([X|Y], S) :- deep_sum(X, P), deep_sum(Y, Q), S is P + Q.

Answer 1

问题出在您的最后一条子句上：

deep_sum([X|Y], M, N) :-  M is P+Q, deep_sum(X,P,N), deep_sum(Y,Q,N).

错误的直接原因是，当执行M is P+Q时，P和Q都不具有值。 只是将其移到后面并不能解决它，该子句还有更多问题。

让我们看一下递归调用。 deep_sum(X,P,N)的意思是“ N是给定累加器P时磁头（X）的深度和”。 这里有两个问题：P没有值，并且N应该是整个列表的总和，而不仅仅是头。

在第二个递归调用中存在相同的问题。 累加器Q还没有值，因此再次将N用作结果。 所以现在N具有3个含义：头部的深和，尾部的深和以及整个列表的深！ 显然那里不对。

让我们尝试说一下递归规则应该如何表现。 结果N应该等于a）当前累加器的总和，b）头的深度之和，c）尾部的深度之和。 a和b可以轻松组合：只需将当前累加器作为递归调用的累加器： deep_sum(X, M, N1) 。 在这里，我使用另一个变量N1来保存此结果。 现在我们只需要将其与尾部的深和相加即可。 同样，我们可以简单地将N1作为累加器传递给递归调用，所有内容都将按预期进行累加。

将所有内容放在一起，您的递归规则应如下所示：

deep_sum([X|Y], M, N) :- 
    deep_sum(X, M, N1), 
    deep_sum(Y, N1, N).

---

为了完整起见，我的deep_sum / 3实现看起来像这样：

deep_sum(X, M, N) :- 
    number(X), 
    N is M + X.
deep_sum([], N, N).
deep_sum([X|Y], M, N) :- 
    deep_sum(X, M, N1), 
    deep_sum(Y, N1, N).

主要区别在于：

• 只有一个递归子句； 处理数字的子句不需要递归。
• number/1而不是atomic/1 ，所以您不会尝试添加字符串左右。
• 重新排列子句的顺序，以在完成计算后不留下任何无用的选择点。