MS Access VB XML解析问题

Question

我正在尝试在MS Access中创建一个表单，该表单允许用户将地址发送给USPS进行验证并获取正确的地址。 我的大部分工作都可以使用，但是对于XML和解析是新手，我正在使用在其他地方找到的代码并试图使其正常工作。 我已经能够发送数据并使用XML接收回响应。 但是我不知道如何解析出节点。 示例我将有一个表单，其中一个人将地址1、2，城市，州，邮编等放入…。我希望结果返回这些表单字段，或者至少返回到这些字段旁边的文本框中。 作为测试，我可以显示从USPS获得的结果，但显然其中包括XML代码。 所以现在我只需要从XML中解析出数据并显示出来即可。 但是我不能只获得我想要的数据。 例如，假设我要从代码中获取地址1，城市，zip5。 就发送数据和接收固定地址而言，这就是我所拥有的。 但是同样，我似乎无法取出数据。

我怀疑基于先前的错误设置cstrXpath不正确。 现在，下面的代码确实显示了包含完整结果的msgbox，包括代码AT MsgBox myDom.XML，但未显示仅显示地址和zip5的消息。

Private Sub Command0_Click()


Const cstrXPath As String = "/Address:Address1/Address2/City/State/Zip5/Zip4"

Dim myDom As MSXML2.DOMDocument
Dim xmlElement As MSXML2.IXMLDOMElement
Dim xmlSelection As MSXML2.IXMLDOMSelection
Dim i As Long
Dim myXML As String

 myXML = "http://production.shippingapis.com/ShippingAPITest.dll?API=Verify&XML=" & _
    "<AddressValidateRequest%20USERID=" & Chr(34) & "XXXXXXACCOUNTXX" & Chr(34) & "><Address>" & _
    "<Address1></Address1>" & _
    "<Address2>6406 Ivy Lane</Address2><City>Greenbelt</City><State>MD</State>" & _
    "<Zip5></Zip5><Zip4></Zip4></Address></AddressValidateRequest>"

'Set myDom = CreateObject("MSXML2.DOMDocument")
Set myDom = New MSXML2.DOMDocument
myDom.async = False
myDom.Load (myXML)

Set xmlSelection = myDom.selectNodes(cstrXPath)
'Debug.Print "xmlSelection.Length: " & xmlSelection.length
'i = 1
For Each xmlElement In xmlSelection
    MsgBox xmlElement.getAttribute("Address1") & xmlElement.getAttribute("Zip5")
 '   i = i + 1
Next xmlElement

    MsgBox myDom.XML
End Sub

Answer 1

这可能并不复杂，但似乎可以完成工作：

Option Compare Database
Option Explicit

Sub xmlParseTest()
    Dim myDom As New MSXML2.DOMDocument
    myDom.SetProperty "SelectionLanguage", "XPath"
    ' test data
    myDom.LoadXML _
            "<?xml version=""1.0""?>" & _
            "<AddressValidateResponse>" & _
                "<Address>" & _
                    "<Address2>6406 IVY LN</Address2>" & _
                    "<City>GREENBELT</City>" & _
                    "<State>MD</State>" & _
                    "<Zip5>20770</Zip5>" & _
                    "<Zip4>1441??</Zip4>" & _
                "</Address>" & _
            "</AddressValidateResponse>" & _
            ""
    Dim addr As MSXML2.IXMLDOMElement
    For Each addr In myDom.SelectNodes("//Address")
        Debug.Print "Start of Address"
        Dim item As MSXML2.IXMLDOMElement
        For Each item In addr.ChildNodes
            Debug.Print "    " & item.BaseName & ": " & item.Text
        Next
        Set item = Nothing
        Debug.Print "End of Address"
    Next
    Set addr = Nothing
    Set myDom = Nothing
End Sub

在“ VBA立即”窗口中产生以下输出：

Start of Address
    Address2: 6406 IVY LN
    City: GREENBELT
    State: MD
    Zip5: 20770
    Zip4: 1441??
End of Address