[英]dynamic pivot for non aggregate
我知道如何动态地枢转,展示,例如, 在这里 。
动态透视图可能不适用于我的场景,其中#source可以包含动态列和动态列值,必须按如下所示对其进行透视:
IF OBJECT_ID('tempdb..#Source') IS NOT NULL DROP TABLE #Source
IF OBJECT_ID('tempdb..#Aim') IS NOT NULL DROP TABLE #Aim
CREATE TABLE #Source
(
ColumnName NVARCHAR(10),
ColumnValue NVARCHAR(10),
Id INT
)
CREATE TABLE #Aim
(
Id INT,
Column1 NVARCHAR(10),
Column2 NVARCHAR(10),
Column3 NVARCHAR(10)
)
INSERT INTO #Source (ColumnName, ColumnValue, Id) VALUES ('Column1', 'Value1', 1);
INSERT INTO #Source (ColumnName, ColumnValue, Id) VALUES ('Column2', 'Value1', 1);
INSERT INTO #Source (ColumnName, ColumnValue, Id) VALUES ('Column1', 'Value2', 2);
INSERT INTO #Source (ColumnName, ColumnValue, Id) VALUES ('Column1', 'Value4', 3);
INSERT INTO #Source (ColumnName, ColumnValue, Id) VALUES ('Column3', 'Value1', 3);
INSERT INTO #Source (ColumnName, ColumnValue, Id) VALUES ('Column3', 'Value3', 4);
SELECT * FROM #Source
INSERT INTO #Aim (Id, Column1, Column2, Column3) VALUES (1, 'Value1', 'Value1', NULL)
INSERT INTO #Aim (Id, Column1, Column2, Column3) VALUES (2, 'Value2', NULL, NULL)
INSERT INTO #Aim (Id, Column1, Column2, Column3) VALUES (3, 'Value4', NULL, 'Value1')
INSERT INTO #Aim (Id, Column1, Column2, Column3) VALUES (4, NULL, NULL, 'Value3')
SELECT * FROM #Aim
我正在尝试实现#Aim的最后一个select语句的输出。 我希望这是自我解释。 这可能吗?
https://www.mssqltips.com/sqlservertip/2783/script-to-create-dynamic-pivot-queries-in-sql-server/
你可以这样做
DECLARE @col_list VARCHAR(max) = (SELECT Quotename(ColumnName) + ','
FROM #Source
GROUP BY ColumnName
ORDER BY ColumnName
FOR xml path('')) -- To create the dynamic column list
SET @col_list = LEFT(@col_list, Len(@col_list) - 1) -- To remove the leading comma
DECLARE @sql NVARCHAR(max)
SELECT @sql = 'select * from #Source
pivot (max(ColumnValue) for ColumnName in ('
+ @col_list + '))pv'
EXEC Sp_executesql @sql -- Execute the dynamic sql
结果:
╔════╦═════════╦═════════╦═════════╗
║ Id ║ Column1 ║ Column2 ║ Column3 ║
╠════╬═════════╬═════════╬═════════╣
║ 1 ║ Value1 ║ Value1 ║ NULL ║
║ 2 ║ Value2 ║ NULL ║ NULL ║
║ 3 ║ Value4 ║ NULL ║ Value1 ║
║ 4 ║ NULL ║ NULL ║ Value3 ║
╚════╩═════════╩═════════╩═════════╝
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.