如何将转义双引号传递给批处理文件

Question

我知道有类似的问题，但有一件事我在答案中找不到。 我正在尝试将以下字符串传递给批处理文件：

hello " world

这只是一个论点。 这是我的批处理文件：

@echo off
@echo %1

现在如果我从命令行运行它，我得到以下结果：

>C:\file.bat "hello "" world"
"hello "" world"

>C:\file.bat "hello \" world"
"hello \"

>C:\file.bat "hello """ world"
"hello """

在所有情况下，我得到了错误的结果，如何逃避双引号并正确传递？ 或者我应该在批处理文件本身中执行任何其他转换步骤？

Answer 1

由于以下两个原因，无法将hello " world的字符串文字值作为批处理参数传递：

1. 关于参数标记化，空间无法转义。 参数始终由不带引号的标记分隔符分隔，即使它们前面有^转义字符。 令牌参数令牌分隔符是{space} ， {tab} ， , ， ; = ，和{0xFF} 。 将标记分隔符作为参数的一部分包含的唯一方法是确保引用分隔符。

2. 在引用的字符串中逃避引用是不可能的。 引号是一个状态机：第一个遇到的引用打开引用语义，随后的引用将其关闭。 下一个引号再次打开它等等。如果引用关闭，那么引用文字可以转义为^"以保持引用。但一旦引用已经开始，那么就没有办法逃避收盘报价：下一个报价总是引用。

因此，无论您如何添加引号和/或转义引号，总会有一个不带引号的空格，因此该字符串将被视为两个参数。

您可以采用Hapax推荐的策略 - 引用整个字符串，并将字符串中的任何引号文字加倍： "Hello "" world" 。

但是我会稍微改变并使用%~1而不是%1来删除外部引号。 那么加倍的报价应该转换回单引号：

@echo off
set "arg1=%~1"
set "arg1=%arg1:""="%"
echo %arg1%

但是将字符串文字作为批处理参数传递还有其他潜在问题。 最阴险的是插入符号加倍。 如果调用者使用CALL，则不可能将带引号的插入符作为参数传递。 我不会进入问题背后的机制。 如果您想了解更多信息，请参阅https://stackoverflow.com/a/4095133/1012053 。 但以下说明了问题：

test.bat的

@echo %1

- 示例cmd会话 -

D:\test>test "^"
"^"

D:\test>call test "^"
"^^"

由于将字符串文字作为批处理参数传递的许多复杂性，高级批处理脚本中使用的最有效策略是将值存储在环境变量中，然后将变量名称作为参数传递。 然后，批处理脚本可以使用延迟扩展来获取正确的值：

test2.bat

@echo off
setlocal enableDelayedExpansion
set "arg1=!%1!"
echo !arg1!

- 示例cmd会话 -

D:\test>set "myVar=Hello world! ^&|<>" How are you doing? !^^^&^|^<^>^"

D:\test>set myVar
myVar=Hello world! ^&|<>" How are you doing? !^&|<>

D:\test>test2 myVar
Hello world! ^&|<>" How are you doing? !^&|<>

D:\test>call test2 myVar
Hello world! ^&|<>" How are you doing? !^&|<>

Answer 2

保持报价的方法是将它们加倍。 然而，这通过了他们两个。 然后，您可以处理输入并删除双打。

使用file.bat "hello "" world" ，我们使用：

@echo off
set param=%1
set param=%param:""="%
echo %param%

（结果： "hello " world" ）

更短的版本：

@echo off
set param=%1
echo %param:""="%