dgtsv-LAPACK不返回答案

Question

我正在尝试使用LAPACK库解决一个简单的方程对角线系统。 下面的代码说明了这一切。

我得到一个充满零的数组（初始化的零），而不是正确的答案。

我检查了输入，尝试使用两个编译器进行编译，一切似乎都很好。 怎么了？

编译行是：

ifort -L/usr/local/lib/ -llapack -lblas tLapack.f90 -o tlapack  
gfortran -L/usr/local/lib/ -llapack -lblas tLapack.f90 -o tlapack  

代码是：

program lapackT

  implicit none

  ! dgtsv( integer(4) :: N,
  !        integer(4) :: NRHS,
  !        real(8)    :: DL[],
  !        real(8)    :: D [],
  !        real(8)    :: DU[],
  !        real(8)    :: B [],
  !        integer(4) :: LDB ,
  !        integer(4) :: info )

  ! [A][x] = [b]
  ! N    - The order of matrix [A] 
  ! NRHS - Number of coluns in [b]
  ! DL   - Array with the subdiag.
  ! D    - Main diagonal.
  ! DU   - Upper Diagonal.
  ! B    - Answer !!
  ! LDB  - length of array [B].
  ! INFO - If = 0 .. Uhul !!.

  real(8), dimension(3) :: mainDiag
  real(8), dimension(2) :: lowerDiag
  real(8), dimension(2) :: upperDiag
  real(8), dimension(3) :: unknow
  real(8), dimension(3) :: equalty

  integer(4) :: info = 0
  integer(4) :: i = 0

  integer(4) :: N    = 3
  integer(4) :: NRHS = 1
  integer(4) :: LDB  = 3

  mainDiag(1) = 2.0d0
  mainDiag(2) = 2.0d0
  mainDiag(3) = 2.0d0

  upperDiag(1) = 3.0d0
  upperDiag(2) = 3.0d0

  lowerDiag(1) = 1.0d0
  lowerDiag(2) = 1.0d0

  equalty(1) = 1.0d0
  equalty(2) = 1.0d0
  equalty(3) = 1.0d0

  unknow = 0.0d0 ! answer

  call dgtsv(N,NRHS,lowerDiag,mainDiag,upperDiag,equalty,LDB,info)



  write(*,*) info

  do i = 1,size(unknow)
    write(*,*) unknow(i)
  end do

  ! Correct answer: unknow = (/-1,1,0/)    ! real(8) values
  ! Answer Im getting: unknow = (/0,0,0/)  ! real(8) values


end program lapackT

Answer 1

如果您查看文档，您会看到在等值参数中返回了答案（即，它覆盖了RHS）-由于未传递信息，它将如何受到调用的影响？ 而且我同意，我相信机器人是有史以来最伟大的设计...

当我在这里时，请了解种类，但是您正在做的事情距今已有25年。 请查看Fortran 90种类参数 。 无论如何，这就是我如何编写您的程序（如今有些人说它也有些过时），并且给出了答案：

ian-admin@agon ~/test/stack $ cat dt.f90
program lapackT

  implicit none

  Integer, Parameter :: wp = Selected_real_kind( 13, 70 )

  real(wp), dimension(3) :: mainDiag
  real(wp), dimension(2) :: lowerDiag
  real(wp), dimension(2) :: upperDiag
  real(wp), dimension(3) :: unknow
  real(wp), dimension(3) :: equalty

  integer :: info = 0
  integer :: i = 0

  integer :: N    = 3
  integer :: NRHS = 1
  integer :: LDB  = 3

  mainDiag(1) = 2.0_wp
  mainDiag(2) = 2.0_wp
  mainDiag(3) = 2.0_wp

  upperDiag(1) = 3.0_wp
  upperDiag(2) = 3.0_wp

  lowerDiag(1) = 1.0_wp
  lowerDiag(2) = 1.0_wp

  equalty(1) = 1.0_wp
  equalty(2) = 1.0_wp
  equalty(3) = 1.0_wp

  unknow = 0.0_wp ! answer

  call dgtsv(N,NRHS,lowerDiag,mainDiag,upperDiag,equalty,LDB,info)



  write(*,*) info

  do i = 1,size(unknow)
    write(*,*) equalty(i)
  end do

  ! Correct answer: unknow = (/-1,1,0/)    ! real(8) values
  ! Answer Im getting: unknow = (/0,0,0/)  ! real(8) values


end program lapackT
ian-admin@agon ~/test/stack $ gfortran -Wall -Wextra -fcheck=all -O -std=f95 dt.f90  -llapack
ian-admin@agon ~/test/stack $ ./a.out
           0
  -1.0000000000000000     
   1.0000000000000000     
   0.0000000000000000E+000
ian-admin@agon ~/test/stack $ 

Answer 2

除非dgtsv通过副作用运行，否则dgtsv语句序列（您的代码，无空行）：

  unknow = 0.0d0 ! answer
  call dgtsv(N,NRHS,lowerDiag,mainDiag,upperDiag,equalty,LDB,info)
  write(*,*) info
  do i = 1,size(unknow)
    write(*,*) unknow(i)
  end do

不会更新unknow 。 怎么可能都不是0.0 s？

是不是结果通过返回equalty在调用dgtsv ？