如何使用XSLT 1.0复制XML中的特定元素

Question

首先，让我提供示例xml，以便大家清楚接下来的内容。

<a>1</a>
<b>1</b>
<c>1</c>
<d>1</d>
<e>1</e>
<f>1</f>

可以将节点从a复制到b，从e复制到f。 我需要忽略节点c和d。

有<xsl:copy>可以复制元素，但是我需要从原始XML中获取特定的元素。

谢谢。

Answer 1

当然，您可以删除所需的元素。 身份转换后，只需在指定的元素上写空模板即可。

源XML

<root>
   <a>1</a>
   <b>1</b>
   <c>1</c>
   <d>1</d>
   <e>1</e>
   <f>1</f>
</root>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:strip-space elements="*"/>

  <!-- Identity Transform -->    
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <!-- Empty Template to Remove Elements -->   
  <xsl:template match="c|d"/>

</xsl:stylesheet>

输出XML

<root>
   <a>1</a>
   <b>1</b>
   <e>1</e>
   <f>1</f>
</root>

或者，选择要保留的特定节点：

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:strip-space elements="*"/>

  <!-- Root Template Match -->    
  <xsl:template match="root">
    <xsl:copy>
      <xsl:apply-templates select="a|b|e|f"/>
    </xsl:copy>
  </xsl:template>

  <!-- Select Particular Elements -->   
  <xsl:template match="a|b|e|f">
      <xsl:copy-of select="."/>
  </xsl:template>

</xsl:stylesheet>