从Xtext DSL导入Java类

Question

我是Xtext的新手。 我在dsl中使用模型类，如下所示：

Model abc:
 variable1
 variable2

并像这样导入类：

import a.b.c

我想做的是，当我说import abc（这是同一目录中的java类）。 编辑器必须识别此abc类，并将其作为模型引用，例如：

型号名称=类名称

变量名=类中的变量。

我也写了一个不同的类，该类在模型类中获取变量的引用。 因此，如果我在该类中说variable1，并且在所有模型中都没有名为variable1的变量，则会出现语法错误。 当我在dsl中编写模型类时，它可以工作，但是我无法使用导入类来做到这一点。

谢谢你的帮助。

Answer 1

这可能是一个起点

grammar org.xtext.example.mydsl.MyDsl with org.eclipse.xtext.xbase.Xbase

generate myDsl "http://www.xtext.org/example/mydsl/MyDsl"

import "http://www.eclipse.org/xtext/common/JavaVMTypes" as types

Model:
    imports=XImportSection?
    elements+=Element*
    ;

Element:
    "element" "{"
        "modelname" "=" type=JvmTypeReference
        "variable" "names" "=" memberReferences+=MemberReference ("," memberReferences+=MemberReference)*
    "}"
;

MemberReference:
    member=[types::JvmField|ID]
;

然后调整范围提供者

package org.xtext.example.mydsl.scoping

import org.eclipse.emf.ecore.EObject
import org.eclipse.emf.ecore.EReference
import org.eclipse.xtext.EcoreUtil2
import org.xtext.example.mydsl.myDsl.Element
import org.xtext.example.mydsl.myDsl.MyDslPackage
import org.eclipse.xtext.scoping.IScope
import org.eclipse.xtext.scoping.Scopes
import org.eclipse.xtext.common.types.JvmDeclaredType
import org.eclipse.xtext.naming.QualifiedName

class MyDslScopeProvider extends AbstractMyDslScopeProvider {

    override getScope(EObject context, EReference reference) {
        if (reference == MyDslPackage.Literals.MEMBER_REFERENCE__MEMBER) {
            val element = EcoreUtil2.getContainerOfType(context, Element)
            if (element != null)  {
                val type = element.type.type
                if (type instanceof JvmDeclaredType) {
                    return Scopes.scopeFor(type.declaredFields, [QualifiedName.create(simpleName)], IScope.NULLSCOPE)
                }
            }
            return IScope.NULLSCOPE
        }
        super.getScope(context, reference)
    }

}

提案提供者

class MyDslProposalProvider extends AbstractMyDslProposalProvider {

    override protected isKeywordWorthyToPropose(Keyword keyword) {
        true
    }

}