批处理文件调用控制台应用程序 - 使 CMD 窗口保持打开状态

Question

我正在通过批处理文件调用 C# 控制台应用程序，以便将应用程序输出发送到带有日期/时间等的文本文件中。

我遇到的问题是，当控制台应用程序完成时，它使批处理窗口保持打开状态，因为有一个 PAUSE（C# 等效项），因此必须按下一个键才能关闭窗口。 这意味着我不知道工作何时完成。

有没有办法在应用程序完成时关闭 CMD 窗口，而不必更改 C# 应用程序代码？

@ECHO================================================================================
@ECHO The Application is currently running and may take some time. Please wait...
@ECHO================================================================================
@ECHO OFF

C:\Applications\Job\Job.exe > C:\Applications\Job\Job_Output\"Output_%date:/=-% %time::=-%.txt"

Answer 1

试试这个（注意echo之后的整理点）：

echo.| C:\Applications\Job\Job.exe > C:\Applications\Job\Job_Output\"Output_%date:/=-% %time::=-%.txt"

我试过pause ，效果很好：

echo.| pause

echo. 不是echo 。 它只是打印一个换行符，这正是触发暂停所需的内容。

Answer 2

如果您的控制台应用程序已经有Console.ReadLine()或Console.ReadKey()方法，则不确定它是否可以工作，但不是仅调用*.exe而是使用Start命令，该命令将在单独的窗口中运行可执行文件，例如

start "MyConsoleTask" C:\Applications\Job\Job.exe > C:\Applications\Job\Job_Output\"Output_%date:/=-% %time::=-%.txt"

Answer 3

如果您无法访问控制台应用程序源代码，您可以尝试一种解决方法

@echo off
@echo================================================================================
@echo The Application is currently running and may take some time. Please wait...
@echo================================================================================

set "timeStamp=%date:/=-%_%time::=-%
set "timeStamp=%timeStamp:~0,-3%"      & rem remove ,centiseconds.

set "logFile=C:\Applications\Job\Job_Output\Output_%timeStamp%.txt"

rem start the exe in the same cmd window
start /B "" """C:\Applications\Job\Job.exe" > "%logFile%"""

rem wait for process startup
ping 1.1.1.1 -n 1 -w 750 >NUL

rem wait for logFile to be closed. This may flag that job.exe has ended
:wait
ping 1.1.1.1 -n 1 -w 50 >NUL & rem this avoids processor load
2>nul (>>"%logFile%" call )||goto :wait

rem send a key to the console. This may be captured by the exe file
set "_vbs_file_=%TEMP%\sendConsole.vbs"
(
  echo/ set oWS ^= CreateObject^("wScript.Shell"^)
  echo/ wScript.Sleep 50
  echo/ oWS.SendKeys "{ENTER}"
)>"%_vbs_file_%"
if exist "%TEMP%\sendConsole.vbs" (set "_spawn_=%TEMP%\sendConsole.vbs") else (set "_spawn_=sendConsole.vbs")
ping 1.1.1.1 -n 1 -w 50 >NUL
start /B /WAIT cmd /C "cls & "%_spawn_%" & del /F /Q "%_spawn_%" 2>NUL"

@echo================================================================================
@echo Process completed. I guess...
@echo================================================================================

exit/B

所以，

start /B ...

在同一个 cmd 窗口中启动job.exe 可执行文件。

:wait
ping 1.1.1.1 -n 1 -w 50 >NUL & rem this avoids processor load
2>nul (>>"%logFile%" call )||goto :wait

等待直到日志文件关闭，所以它可能表明前一个过程已经结束。

set "_vbs_file_=%TEMP%\sendConsole.vbs"
(
  echo/ set oWS ^= CreateObject^("wScript.Shell"^)
  echo/ wScript.Sleep 50
  echo/ oWS.SendKeys "{ENTER}"
)>"%_vbs_file_%"
if exist "%TEMP%\sendConsole.vbs" (set "_spawn_=%TEMP%\sendConsole.vbs") else (set "_spawn_=sendConsole.vbs")
ping 1.1.1.1 -n 1 -w 50 >NUL
start /B /WAIT cmd /C "cls & "%_spawn_%" & del /F /Q "%_spawn_%" 2>NUL"

将回车键发送到控制台，因此等待击键的进程可能会捕获它。

注意：只有当 IP 无法访问时， ping 等待技巧才能正常工作。

注意：这里讨论了调用和/或转到技巧

Answer 4

我们必须在这里模拟按键，因此我们应该玩弄键盘缓冲区。

我不是批处理专家，这是我在搜索如何使用批处理按键时找到的答案：

@if (@CodeSection == @Batch) @then
@echo off
set SendKeys=CScript //nologo //E:JScript "%~F0"
rem Open the command here
start "" /B Job.exe > JobOutput.txt
rem sends the keys composing the string "I PRESSED " and the enter key
%SendKeys% "I PRESSED {ENTER}"
goto :EOF

@end

// JScript section
WScript.CreateObject("WScript.Shell").SendKeys(WScript.Arguments(0));

来源：

• 使用批处理文件按键盘键
• GnuWin32 openssl s_client conn 到 WebSphere MQ 服务器未在 EOF 关闭，挂起