使用VBA清除工作表中所有不包含公式的单元格？

Question

我正在使用以下代码来清理所有不包含公式的单元格。

Sub DoNotContainClearCells()


Dim rng As Range
Dim cell As Range
Dim ContainWord As String

'What range ?
  Set rng = Worksheets("Datenbasis").Range("A5:Z100")

'What I am looking for?
  ContainWord = "="


  For Each cell In rng.Cells
    If cell.Find(ContainWord) Is Nothing Then cell.Clear
  Next cell

End Sub

但是我收到运行时错误1004，只删除了第一列。 我该如何处理该错误？ 有什么更好的方法可以从不包含公式的工作表中删除单元格？

Answer 1

考虑：

Sub DoNotContainClearCells()    
    Dim rng As Range
    Set rng = Worksheets("Datenbasis").Range("A5:Z100")
    rng.Cells.SpecialCells(xlCellTypeFormulas).Clear
End Sub

编辑＃1：

如果要清除不包含公式的单元格，请执行以下操作：

 Sub DoNotContainClearCells()    
        Dim rng As Range
        Set rng = Worksheets("Datenbasis").Range("A5:Z100")
        rng.Cells.SpecialCells(xlCellTypeConstants).Clear
    End Sub

将不理会公式单元格！。

Answer 2

请尝试以下

Sub DoNotContainClearCells()
    Dim rng As Range
    Dim cell As Range
    'What range ?
    Set rng = Worksheets("Datenbasis").Range("A5:Z100")
    For Each cell In rng.Cells
      If Not cell.HasFormula Then cell.Clear
    Next cell
End Sub