SAS％DO循环以检索多个数据集

Question

我正在尝试使用％DO循环来附加多个每月数据文件。 这是我到目前为止的代码：

options mprint symbolgen source mlogic merror syntaxcheck ;


%MACRO INT;

%DO i=01 %TO 03 %BY 1;

libname appd "Qual1.Qual2.Qual3.QUAL416&i." disp=shr;

data work&i.;
set appd.file;
run;

data final;
set work;
run;

proc append data=work&i.
            base=final;
run;

%MEND;

%INT;

我遇到一个错误：

警告：当前正在处理的带引号的字符串的长度超过262个字符。 您可能有不平衡的引号。

我以前从未收到过此错误，我也不完全知道这意味着什么。 我正在尝试创建此宏来添加今年的一些文件，但理想情况下，它会跨越多年。 即更改mtro16＆i。 去地铁＆i。 除非我不想显式地编码%DO i=1601 %TO 1612 %BY 1 ，因为我每年都必须对其进行更改，例如，如果我从2010年开始，则必须编码2010，然后直到2011年为止，都是针对2011年的单独%DO语句，直到2016年。这听起来并不多，但是十多年以来就可以了。

更新：我更改了代码以包括以下内容：

`%DO i=1005 %TO 1607;
%IF i=1013 %THEN %DO i=1101 %TO 1112;
/*%ELSE %IF i=1113 %THEN %DO i=1201 %TO 1212;*/
/*%ELSE %IF i=1213 %THEN %DO i=1301 %TO 1312;*/
/*%ELSE %IF i=1313 %THEN %DO i=1401 %TO 1412;*/
/*%ELSE %IF i=1413 %THEN %DO i= 1501 %TO 1512;*/
/*%ELSE %IF i=1513 %THEN %DO i=1601 %TO 1607;*/`

有点过时，但我认为只循环到年末然后在i=1012 to i=1101之后开始下一次迭代是可行的。 但是，这就是我的日志中发生的事情：

 MLOGIC(INT):  %DO loop index variable I is now 1012; loop will iterate again. 
 MLOGIC(INT):  %IF condition i=1013 is FALSE 
 MLOGIC(INT):  %DO loop index variable I is now 1013; loop will iterate again. 
 MLOGIC(INT):  %IF condition i=1013 is FALSE

SAS如何治疗这种%IF疾病？ 它告诉我变量i = 1013 ， %IF条件i=1013为FALSE？ 为什么这不是TRUE？

Answer 1

这是进行这种循环的一种方法：

%macro month_loop(MTH_FROM, MTH_TO);
  %local T_MTH_FROM T_MTH_TO MTH_DIFF CUR_MTH MTH_OFFSET;
  %let T_MTH_FROM = %sysfunc(inputn(&MTH_FROM,yymmn.));
  %let T_MTH_TO   = %sysfunc(inputn(&MTH_TO,yymmn.));
  %let MTH_DIFF   = %sysfunc(intck(month,&T_MTH_FROM,&T_MTH_TO));

  %do MTH_OFFSET = 0 %to &MTH_DIFF;
    %let CUR_MTH = %sysfunc(intnx(month,&T_MTH_FROM,&MTH_OFFSET), yymmn4.);
    %put CUR_MTH = &CUR_MTH;
  %end;
%mend;

%month_loop(1001,1607);

Answer 2

我认为在处理日期时，应始终实际使用日期值，而不要尝试通过使用年或月或其他类似的“快捷方式”来缩短日期。 以我的经验，这些总是会导致代码混乱或错误。

下面的宏显示了如何传递开始日期和结束日期（甚至不必是每月的1号），它将返回适当的每月名称。 然后，您可以根据需要proc append进行修改以使其与proc append或其他代码一起使用。

实际上，它需要2个日期值作为参数。 然后，它使用%do %while循环和intnx()函数一次从开始日期到结束日期循环1个月。 我使用%sysfunc(sum(),yymmn4.)为您的每月数据集计算所需的格式，并将其打印到日志中。

码：

%macro append_monthly(iStart_date=, iEnd_date=);

  %local tmp_date id;
  %let tmp_date = %sysfunc(intnx(month,&iStart_date,0,beginning)) ;

  %do %while (&tmp_date le &iEnd_date);

    %let id = %sysfunc(sum(&tmp_date),yymmn4.);
    %put &=id;

    %let tmp_date = %sysfunc(intnx(month,&tmp_date,1,beginning)) ;

  %end;

%mend;
%append_monthly(iStart_date=%sysfunc(mdy(1,1,2010)),  iEnd_date=%sysfunc(mdy(1,1,2013)) );

请注意， %sysfunc(sum(&tmp_date),yymmn4.)是使用宏格式化数字时的一种快捷方式。 %sysfunc()要求我们提供一个函数作为第一个参数，您可以选择提供格式作为第二个参数。 sum()函数很方便，因为它使数值保持不变。

输出：

ID=1001
ID=1002
ID=1003
...
ID=1011
ID=1012
ID=1101
ID=1102
ID=1103
...
ID=1110
ID=1111
ID=1112
ID=1201
ID=1202
ID=1203
...
ID=1210
ID=1211
ID=1212
ID=1301

Answer 3

遵循您的逻辑有些困难，但是看起来您只想这样做：

data final;
  set appd.file work01-work03 ;
run;