在 ColdFusion 中为 SOAP 调用添加 cookie 到 HTTP 标头

Question

我基本上想在通过 ColdFusion 调用 SOAP Web 服务时将ASP.NET_SessionId cookie 添加到我的 HTTP 请求标头中。

Web 服务注册在 ColdFusion 中Application.cfc组件的OnApplicationStart函数中。

<cfscript>
    objSoapHeader = XmlParse("<wsse:Security mustUnderstand=""true"" xmlns:wsse=""http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd""><wsse:UsernameToken><wsse:Username>MY_USERNAME</wsse:Username><wsse:Password>MY_PASSWORD</wsse:Password></wsse:UsernameToken></wsse:Security>");
    Application.UserWebService = CreateObject("webservice","MY_URL/UserService.asmx?WSDL");
    addSOAPRequestHeader(Application.UserWebService,"","",objSoapHeader,true);
</cfscript>

我的网络服务是这样调用的：

<cfset Result = "#Application.UserWebService.SomeFunction("1", "DATA")#">

为了让 .Net 服务器（Web 服务所在的位置）记住我的会话状态，我必须在 HTTP 请求标头中传递ASP.NET_SessionId cookie，但不知道这在 ColdFusion 中是否可行。

我已经研究了几个小时，但到目前为止还没有任何结果，那么有没有人成功地做到了这一点？

Answer 1

简答：

对于 CF9 / Axis1，请尝试在 Web 服务对象上启用会话。

ws = createObject("webservice", "http://localhost/MyWebService.asmx?wsdl");
ws.setMaintainSession( true );

对于 CF10+ / Axis2，请参阅下面的更长答案：

---

（免责声明：使用cfhttp可能更简单，但我很好奇并做了一些挖掘......）

从我读到的内容来看，由于 CF10+ 将Axis2用于 Web 服务，因此应该可以使用底层方法通过 HTTP cookie 维护会话状态。

• 如何在 ColdFusion SOAP 请求中设置 Cookie -（大约 2006 年） -为较旧版本的 CF/Axis 编写，因此其中一些已经过时，但它仍然提供了对一般概念的很好的概述。

• 在 Axis2 中维护会话

• Java 轴 Web 服务客户端 setMaintainSession 对多个服务（cookie？）

• Axis2 手动管理会话 Cookie

使用上面的链接，我使用基本 Web 服务组合了一个快速 POC，并能够从 Web 服务客户端响应中提取 cookie 标头：

// make initial request
ws = createObject("webservice", "http://localhost/MyWebService.asmx?wsdl");
ws.firstMethod();

// For maintainability, use constants instead of hard coded strings
wsdlConstants = createObject("java", "org.apache.axis2.wsdl.WSDLConstants");

// Extract headers 
operation = ws._getServiceClient().getLastOperationContext();
context = operation.getMessageContext( wsdlConstants.MESSAGE_LABEL_IN_VALUE  );
headers = context.getProperty( context.TRANSPORT_HEADERS );

然后设置 cookie 并指示 Web 服务客户端将其与后续请求一起发送：

if ( structKeyExists(headers, "Set-Cookie") ) {
    // include http cookies with request
    httpConstants = createObject("java", "org.apache.axis2.transport.http.HTTPConstants");
    options = ws._getServiceClient().getOptions();
    options.setManageSession( true );
    options.setProperty( httpConstants.COOKIE_STRING, headers["Set-Cookie"] );
}

// ... more requests
ws.secondMethod();
ws.thirdMethod();

注意：旁注，我注意到您将实例存储在共享应用程序范围内。 请记住，Web 服务实例可能不是线程安全的。

Answer 2

在 CFHPPT 标签中，使用CFHTTPPARAM设置 cookie