如果同一行中的一系列单元格发生任何更改，Excel VBA将更新单元格中的日期

Question

我有一个代码，如果在F列同一行的单元格中进行了任何更改，日期将在D列的单元格中更新：

Private Sub Worksheet_Change(ByVal Target As Range)
' Code to put the date of the latest update following a change in the corresponding cell in column F
Dim WorkRng As Range
Dim rng As Range
Dim xOffsetColumn As Integer
Set WorkRng = Intersect(Application.ActiveSheet.Range("F:F"), Target)
xOffsetColumn = -2 'The date is put 2 columns to the left of column F
If Not WorkRng Is Nothing Then
    Application.EnableEvents = False
    For Each rng In WorkRng
       If Not VBA.IsEmpty(rng.Value) Then
          rng.Offset(0, xOffsetColumn).Value = Now
          rng.Offset(0, xOffsetColumn).NumberFormat = "dd/mm/yyyy"
       Else
          rng.Offset(0, xOffsetColumn).ClearContents
       End If
   Next
   Application.EnableEvents = True
End If
End Sub

现在，我需要调整此代码，以便在F到K列的同一行中的单元格中进行任何更改的情况下，更新D列中的单元格的日期。

我对VBA的了解很少，对于在改编代码方面提供的任何帮助将不胜感激。

Answer 1

这似乎起作用：

Private Sub Worksheet_Change(ByVal Target As Range)
' Code to put the date of the latest update following a change in the corresponding cell in column F
    Dim WorkRng As Range, roww As Long
    Dim rng As Range
    Set WorkRng = Intersect(Range("F:K"), Target)
    If Not WorkRng Is Nothing Then
        Application.EnableEvents = False
            For Each rng In WorkRng
                roww = rng.Row
                If Not rng.Value = "" Then
                    Cells(roww, "D").Value = Now
                    Cells(roww, "D").NumberFormat = "dd/mm/yyyy"
                Else
                    Cells(roww, "D").ClearContents
                End If
            Next
        Application.EnableEvents = True
    End If
End Sub

我们只是不使用OFFSET()