Haskell，类中的函数声明

Question

我试图为多态类树创建一些实例，但我不明白，

看，我的代码是：

data BTree a = BLeaf a | BBranch a (BTree a) (BTree a) deriving(Show)
data TTree a = TLeaf a | TBranch a (TTree a) (TTree a) (TTree a) deriving(Show)

class Tree a where

    getName :: a -> a -- How should i declare this function?

instance Tree (BTree a) where

    getName (BLeaf name) = name
    getName (BBranch name lhs rhs) = name

instance Tree (TTree a) where

    getName (TLeaf name) = name
    getName (TBranch name lhs mhs rhs) = name

test1 = getName (BLeaf 1)
test2 = getName (TLeaf 1)

GHCI说：

Couldn't match expected type `a' with actual type `BTree a'

那么，我应该如何声明getName-function？

Answer 1

对类型构造函数使用类型参数t （如BTree或TTree ，与BTree a和TTree a ）：

class Tree t where
    getName :: t a -> a

instance Tree BTree where
    getName (BLeaf name) = name
    getName (BBranch name lhs rhs) = name

如果您需要根据元素类型a改变实例，则需要多参数类：

{-# LANGUAGE MultiParamTypeClasses #-}

class Tree t a where
    getName :: t a -> a

instance Tree BTree Int where
    getName (BLeaf name) = name+1
    getName (BBranch name lhs rhs) = name*2

instance Tree BTree Char where
    getName (BLeaf name) = name
    getName (BBranch name lhs rhs) = name

可能你不需要这么普遍。