如何从字典视图中发现 Oracle 12c 关联数组的索引类型？

Question

使用 Oracle 12c，我有以下 PL/SQL 包

CREATE OR REPLACE PACKAGE x AS
  TYPE t IS TABLE OF NUMBER INDEX BY PLS_INTEGER;
  FUNCTION f RETURN t;
END x;
/

我现在想动态发现上述函数f的返回类型：

SELECT *
FROM all_arguments
WHERE package_name = 'X';

这个查询产生了一些类似的东西

...可以使用花哨的递归查询将其解析为有用的数据结构，以防万一表包含记录，而不是数字（例如，就像本文中针对PL/SQL RECORD那个）。

然而，我在字典视图中找不到的是对关联数组的索引类型的正式引用，即PLS_INTEGER 。 有没有办法从不同的角度发现它？

请注意，我想避免解析ALL_IDENTIFIERS的内容，因为我不能在任何目标系统上依赖PLSCOPE_SETTINGS='IDENTIFIERS:ALL' 。

Answer 1

请原谅我犯了罪：

WITH
  FUNCTION index_type(type_owner VARCHAR2, type_name VARCHAR2, type_subname VARCHAR2) 
  RETURN VARCHAR2 IS
    l_result VARCHAR2(50) := 'UNKNOWN';
  BEGIN
    EXECUTE IMMEDIATE q'[
      DECLARE
        l_result VARCHAR(50);
        v "]' || type_owner || '"."' || type_name || '"."' || type_subname || q'[";
      BEGIN
        BEGIN
          v('A') := NULL;
          l_result := 'VARCHAR2';
        EXCEPTION
          WHEN OTHERS THEN
            BEGIN
              v(1) := NULL;
              l_result := 'PLS_INTEGER';
            EXCEPTION
              WHEN OTHERS THEN l_result := 'UNKNOWN';
            END;
        END;

        :result := l_result;
      END;]' USING OUT l_result;

    RETURN l_result;
  EXCEPTION
    WHEN OTHERS THEN RETURN SQLERRM;
  END index_type;
SELECT 
  type_owner, type_name, type_subname,
  index_type(type_owner, type_name, type_subname) AS index_type
FROM all_arguments
WHERE data_type = 'PL/SQL TABLE';

这产生了预期的结果：

当然，类型定义需要更多细节，包括长度、精度等，但这对我来说已经足够了。