在C＃或VBA中以编程方式将Jpeg图像插入到Visio绘图中

Question

有没有办法使用C＃或VBA将jpeg图像插入到visio中？ 插入后有没有办法格式化它的属性，如宽度，高度，放置在绘图上的位置？

Answer 1

将图像导入Visio时，它们会被包装成标准形状（具有VisTypeForeignObject的Type属性）。

从那里你只是在谈论ShapeSheet中的单元格。 （有关ShapeSheet的更多详细信息，请参阅此帖子http://visualsignals.typepad.co.uk/vislog/2007/10/just-for-starte.html ）

因此，您可以首先在Visio上使用宏录制器来完成此类操作。 将图像拖到页面上将产生如下输出：

Sub Macro1()

    'Enable diagram services
    Dim DiagramServices As Integer
    DiagramServices = ActiveDocument.DiagramServicesEnabled
    ActiveDocument.DiagramServicesEnabled = visServiceVersion140 + visServiceVersion150

    Dim UndoScopeID2 As Long
    UndoScopeID2 = Application.BeginUndoScope("Auto Size Page")
    Application.ActiveWindow.Page.AutoSize = False
    Application.EndUndoScope UndoScopeID2, True

    Dim UndoScopeID3 As Long
    UndoScopeID3 = Application.BeginUndoScope("Insert")
    Application.ActiveWindow.Page.Import "C:\SomeImage.jpg"
    Application.EndUndoScope UndoScopeID3, True

    ActiveWindow.DeselectAll
    ActiveWindow.Select Application.ActiveWindow.Page.Shapes.ItemFromID(1), visSelect
    Application.ActiveWindow.Selection.Move 2.129396, -0.904364

    Dim UndoScopeID4 As Long
    UndoScopeID4 = Application.BeginUndoScope("Size Object")
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).CellsSRC(visSectionObject, visRowXFormOut, visXFormPinX).FormulaU = "46.261665987369 mm"
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).CellsSRC(visSectionObject, visRowXFormOut, visXFormPinY).FormulaU = "212.02916285428 mm"
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).CellsSRC(visSectionObject, visRowXFormOut, visXFormWidth).FormulaU = "103.47666530807 mm"
    Application.EndUndoScope UndoScopeID4, True

    Dim UndoScopeID5 As Long
    UndoScopeID5 = Application.BeginUndoScope("Size Object")
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).CellsSRC(visSectionObject, visRowXFormOut, visXFormPinX).FormulaU = "46.261665987369 mm"
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).CellsSRC(visSectionObject, visRowXFormOut, visXFormPinY).FormulaU = "185.77916321819 mm"
    Application.ActiveWindow.Page.Shapes.ItemFromID(1).CellsSRC(visSectionObject, visRowXFormOut, visXFormHeight).FormulaU = "73.441667394486 mm"
    Application.EndUndoScope UndoScopeID5, True

    'Restore diagram services
    ActiveDocument.DiagramServicesEnabled = DiagramServices

End Sub

宏录制器根据当前选择进行操作，但您不需要。 此外，它使用SRC（Section，Row，Column）语法而不是更简单的单元名称语法。 所以上面的翻译可能是这样的：

Sub TestAddImage()
    Call DropImage(ActivePage, "C:\SomeImage.jpg")
End Sub

Private Sub DropImage(ByRef vPag As Visio.Page, imageFile As String)

If Not vPag Is Nothing Then
    Dim newShp As Visio.Shape
    Set shpNew = vPag.Import(imageFile)
    'Set position
    shpNew.CellsU("PinX").FormulaU = "75mm"
    shpNew.CellsU("PinY").FormulaU = "175mm"
    'Set size
    shpNew.CellsU("Width").FormulaU = "100mm"
    shpNew.CellsU("Height").FormulaU = "80mm"
End If

End Sub

AC＃版本看起来像这样：

void Main()
{
    var vApp = MyExtensions.GetRunningVisio();
    DropImage(vApp.ActivePage, @"C:\SomeImage.jpg");
}

private void DropImage(Visio.Page vPag, string imageFile)
{
    if (vPag != null)
    {
        var shpNew = vPag.Import(imageFile);
        //Set position
        shpNew.CellsU["PinX"].FormulaU = "75mm";
        shpNew.CellsU["PinY"].FormulaU = "175mm";
        //Set size
        shpNew.CellsU["Width"].FormulaU = "100mm";
        shpNew.CellsU["Height"].FormulaU = "80mm";
    }
}

请注意， GetRunningVisio是我与LinqPad一起使用的扩展方法：

http://visualsignals.typepad.co.uk/vislog/2015/12/getting-started-with-c-in-linqpad-with-visio.html

...但是你如何掌握应用程序对象取决于你。