SAS-在宏中调用proc sql之后的宏

Question

这是新内容，因此，如果我做错了什么，我深表歉意。 我也是SAS的新用户。

我创建了一个宏，该宏首先调用proc sql，该proc创建一个特定的表，该表我希望将其传递给另一个宏（在第一个宏内部）。

%Macro Mc_Copy_Table (TABLE_NAME);
  proc sql;
    create table &TABLE_NAME as 
    select *
    from OR_IN.&TABLE_NAME;

    connect using OR_OUT;
    execute (truncate table &TABLE_NAME) By OR_OUT;
    disconnect from OR_OUT;
  quit;

  %MC_obsnvars(&TABLE_NAME);

  %put &Nobs;
  %if &Nobs > 100000 %then
    %do; /* use of the sql loader */
    proc append base = OR_OU. &TABLE_NAME (&BULKLOAD_OPTION)
                data = &TABLE_NAME;
    run;
    %end;
  %else
    %do;
    proc append base = OR_OU. &TABLE_NAME (Insertbuff=10000)
                data = &TABLE_NAME;
    run;
    %end;
%Mend Mc_Copy_Table;

Mc_Obsnvars宏使用attrn函数从给定的数据集中获取观察数（首先打开数据集）。 根据观察的次数，我的程序是否使用sqlloader。 OR_IN和OR_OUT是libname（Oracle引擎）。

当执行宏Mc_Copy_Table时，以TABLE1作为参数，首先执行Mc_Obsnvars，这将尝试打开尚不存在的TABLE1。 proc sql之后执行。

为什么宏在proc sql之前执行？ 有什么办法让proc sql首先执行？ 将proc sql部分放在宏中并不能解决问题。 谢谢 ：）

Answer 1

我认为您有语法问题，正如昆汀在他的评论中提到的那样。 这对我来说行得通：

%macro copy_table(intable, outtable);
proc sql noprint;
create table &outtable as
select * from &intable;

%count_obs(&outtable);
%put NOBS:&nobs;
quit;
%mend;

%macro count_obs(table);
%global nobs;
select count(*) into :nobs trimmed from &table;
%mend;

data test;
do i=1 to 10;
    output;
end;
run;

%copy_table(test,test2);

但是请注意，您不必进行计数。 PROC SQL中有一个自动变量，称为&sqlobs具有上一次查询返回的记录数。

因此，我认为这为您提供了所需的东西：

%macro copy_table(intable, outtable);
proc sql noprint;
create table &outtable as
select * from &intable
where i < 5;

%let nobs=&sqlobs;
%put NOBS:&nobs;
quit;
%mend;
%copy_table(test,test2);