如何从Perl中的现有哈希创建匿名哈希？

Question

如何从现有哈希创建匿名哈希？

对于数组，我使用：

@x = (1, 2, 3);
my $y = [@x];

但我找不到如何为哈希做同样的事情：

my %x = ();
my $y = ???;

谢谢

Answer 1

为什么需要匿名哈希？ 虽然答案告诉你各种方法可以制作一个匿名哈希，但我们不知道它们中的任何一个是否是你想要做的任何事情的正确解决方案。

如果您想要一个可以在不打扰原始数据的情况下修改的独特副本，请使用Perl附带的Storable中的dclone 。 它会创建数据结构的深层副本：

use Storable qw(dclone);
my $clone = dclone \%hash;

考虑戴夫韦伯的答案，但附加一层参考。 c的键的值是另一个哈希引用：

use Data::Dumper;

my %original = ( a => 1, b => 2, c => { d => 1 } );
my $copy = { %original };

print 
    "Before change:\n\n",
    Data::Dumper->Dump( [ \%original], [ qw(*original) ] ),
    Data::Dumper->Dump( [ $copy ], [ qw(copy) ] ),
    ;

$copy->{c}{d} = 'foo';

print 
    "\n\nAfter change:\n\n",
    Data::Dumper->Dump( [ \%original], [ qw(*original) ] ),
    Data::Dumper->Dump( [ $copy ], [ qw(copy) ] ),
    ;

通过检查输出，您会看到即使您有匿名哈希，它仍然链接到原始：

Before change:

%original = (
              'c' => {
                       'd' => 1
                     },
              'a' => 1,
              'b' => 2
            );
$copy = {
          'c' => {
                   'd' => 1
                 },
          'a' => 1,
          'b' => 2
        };


After change:

%original = (
              'c' => {
                       'd' => 'foo'
                     },
              'a' => 1,
              'b' => 2
            );
$copy = {
          'c' => {
                   'd' => 'foo'
                 },
          'a' => 1,
          'b' => 2
        };

Answer 2

my $new_hash = { %existing_hash };

请注意，此解决方案不会进行深层复制。 阅读brian的答案进行解释。

Answer 3

我想你在这里需要小心。 考虑以下哈希：

my %hash = (1 => 'one',2 => 'two');

有两种方法可以从中获得参考：

my $ref = \%hash;
my $anon = {%hash};

$ref是对原始哈希的引用，可以类似于%hash 。 $anon是对原始哈希的匿名副本的引用; 它将具有相同的数据，但更改它不会更改原始哈希，反之亦然。

因此，例如，从这两个语句开始将具有相同的输出

print $ref->{1},"\n";
> one
print $anon->{1},"\n";
> one

但是，如果我更改原始哈希：

$hash{1} = "i";

他们两个print语句将输出不同的值：

print $ref->{1},"\n";
> i
print $anon->{1},"\n";
> one

Answer 4

如果你有

my %hash = ...

那么你可以做到

my $hashref = \%hash;

Answer 5

这里似乎有两件事情，答案分为回答两个不同的可能问题。

1. 你想要一个匿名哈希。 简单。 你可以一步完成。
2. 您需要现有哈希的匿名副本。 正如Dave Webb和brian建议的那样，如果你想要一个引用，可能就是这样 ，但是你不想篡改原始哈希。 也很容易。 （嗯，不完全是这样的：看看brian关于深拷贝细节的答案。）

如果你想要1，请执行以下操作：

my $hash_ref = { foo => 1, bar => 2 };

如果你想要2，请执行以下操作：

my %hash = ( foo => 1, bar => 2 );

# Then later
my $anon_copy_hash_ref = { %hash };

（这些名字不适合黄金时段。）我的副本也没有为黄金时间做好准备。 请参阅brian的帖子，以获得更全面，更精确的讨论。

Answer 6

使用：

$hashref = {};

Answer 7

快速/简单的方法来实现深层复制：

use FreezeThaw qw(freeze thaw);
$new = thaw freeze $old;