[英]ActionScript 3.0 TransformGestureEvent and MouseEvent
[英]ActionScript 3 TransformGestureEvent not working on SWF MovieClip
下午好,
我在舞台上添加了SWF并将其转换为MovieClip,并给了MovieClip和floorplanMC的实例名称,现在我正尝试将TransformGestureEvent应用于floorplanMC,但是当我对其进行测试时,它无法正常工作我将执行完全相同的步骤,但是使用jpg而不是SWF,它有时仅响应TransformGestureEvent,但是使用jpg每次都响应。 为什么这不适用于SWF但适用于JPG?
这是我的代码:
floorplanMC.addEventListener(TransformGestureEvent.GESTURE_ZOOM, zoomFloorplan);
floorplanMC.addEventListener(MouseEvent.MOUSE_DOWN, dragStartFloorplan);
floorplanMC.addEventListener(MouseEvent.MOUSE_UP, dragEndFloorplan);
这是方法
function zoomFloorplan (event:TransformGestureEvent):void{
myTimerModel.stop();
myTimerModel.reset();
myTimerModel.start();
var locX:Number=event.localX;
var locY:Number=event.localY;
var stX:Number=event.stageX;
var stY:Number=event.stageY;
var prevScaleX:Number=floorplanMC.scaleX;
var prevScaleY:Number=floorplanMC.scaleY;
var mat:Matrix;
var externalPoint=new Point(stX,stY);
var internalPoint=new Point(locX,locY);
floorplanMC.scaleX *= event.scaleX;
floorplanMC.scaleY *= event.scaleY;
if(event.scaleX > 1 && floorplanMC.scaleX > 6){
floorplanMC.scaleX=prevScaleX;
floorplanMC.scaleY=prevScaleY;
}
if(event.scaleY > 1 && floorplanMC.scaleY > 6){
floorplanMC.scaleX=prevScaleX;
floorplanMC.scaleY=prevScaleY;
}
if(event.scaleX < 1.1 && floorplanMC.scaleX < 1){
floorplanMC.scaleX=prevScaleX;
floorplanMC.scaleY=prevScaleY;
}
if(event.scaleY < 1.1 && floorplanMC.scaleY < 1){
floorplanMC.scaleX=prevScaleX;
floorplanMC.scaleY=prevScaleY;
}
mat=floorplanMC.transform.matrix.clone();
MatrixTransformer.matchInternalPointWithExternal(mat,internalPoint,externalPoint);
floorplanMC.transform.matrix=mat;
}
function dragStartFloorplan(e:MouseEvent):void
{
myTimerModel.stop();
myTimerModel.reset();
myTimerModel.start();
if(floorplanMC.scaleX > 1 && floorplanMC.scaleY > 1)
{
floorplanMC.startDrag(false, new Rectangle(0,500,-floorplanMC.width + stage.stageWidth, -floorplanMC.height + 1187));
}
}
function dragEndFloorplan(e:MouseEvent):void
{
myTimerModel.stop();
myTimerModel.reset();
myTimerModel.start();
floorplanMC.stopDrag();
}
这些事件只会触发您的SWF具有背景的部分。 透明区域不会触发事件。
一种简单的解决方案是在子SWF文件内部绘制一个sprite层。
var bg:Sprite = new Sprite();
bg.graphics.beginFill(0xFFFFFF);
bg.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight)
bg.graphics.endFill();
addChild(bg);
为了演示,我们将创建两个.swf
文件。 第一个(孩子)只有一系列的小节。 没有任何事件监听器。
// Child.swf
var size:Number = 50;
for (var i:int = 0; i < stage.stageWidth/(size*2); i++) {
var box:Sprite = new Sprite();
box.graphics.beginFill(0x008cc6);
box.graphics.drawRect(0, 0, size, stage.stageHeight)
box.graphics.endFill();
addChild(box);
box.x = i * (size*2);
}
第二个(父级)加载子级,并将侦听器附加到加载器(swf的最高容器)。 如果单击一个条,则所有条变为绿色。 但是,请注意,单击条之间的空白不会产生任何结果。
// Parent.swf
import flash.display.Loader;
import flash.events.MouseEvent;
import flash.display.Sprite;
import fl.motion.Color;
var loader:Loader = new Loader();
loader.load(new URLRequest("child.swf"));
addChild(loader);
loader.addEventListener("mouseDown", cursor);
loader.addEventListener("mouseUp", cursor);
function cursor(e:MouseEvent):void {
var box:Sprite = e.target as Sprite;
var c:Color = new Color();
if (box != null) {
switch (e.type) {
case "mouseDown":
c.setTint(0x00d719, 1);
loader.transform.colorTransform = c;
break;
case "mouseUp":
c.setTint(0x00, 0);
loader.transform.colorTransform = c;
break;
}
}
}
现在,让我们使用解决方案中提供的后台代码重新编译子级。 这是修改后的子代码。
// Child
var bg:Sprite = new Sprite();
bg.graphics.beginFill(0xFFFFFF);
bg.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight)
bg.graphics.endFill();
addChild(bg);
var size:Number = 50;
for (var i:int = 0; i < stage.stageWidth/(size*2); i++) {
var box:Sprite = new Sprite();
box.graphics.beginFill(0x008cc6);
box.graphics.drawRect(0, 0, size, stage.stageHeight)
box.graphics.endFill();
addChild(box);
box.x = i * (size*2);
}
编译父对象,您会注意到单击任何地方(包括在条之间)将生成事件。
声明:本站的技术帖子网页,遵循CC BY-SA 4.0协议,如果您需要转载,请注明本站网址或者原文地址。任何问题请咨询:yoyou2525@163.com.