UFT不会在Web表格中单击

Question

我在使用UFT时遇到问题。 我有一个网络表格。 我记录了Webtable，然后将Webtable从OR拖到编辑器中。

然后，我进行了如下修改。 单元格1和单元格2返回正确的数据。 在单元内，我只有文本。

cell1 = Browser("Create").Page("Create").WebTable("First").GetCellData(2,1)
print cell1
cell2 = Browser("Create").Page("Create").WebTable("First").GetCellData(3,1)
print cell2

Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "WebElement",0).click

set objLink =Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "WebElement",0)
objLink.Click

set objLink =Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "Link",0)
objLink.Click

它正在查找Web表并返回数据，但未单击该行。 如何单击Web表中的第一行？

Answer 1

首先，您需要确保Web表格的cell（2,1）中具有链接。 为此，检查对象的存在：

set objLink =Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "Link",0)
msgbox objLink.Exist(2)

如果返回True ，那么我们将继续前进。

---

尝试在运行时将ReplayType设置更改为2 ，如下所示：

set objLink =Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "Link",0)
setting.webpackage("replayType") = 2      'Runs mouse operations using the mouse. It will move the mouse pointer physically to the position where click will be performed
objLink.highlight
objLink.click
setting.webpackage("replayType") = 1      'Changing back to Event. Runs mouse operations using browser events.

您也可以从此处手动更改replayType设置：工具>选项> Gui测试> Web>高级>运行设置>重放类型

---

如果这不起作用，则可以在链接对象上触发Click事件 ，如下所示：

set objLink = Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "Link",0)
objLink.highlight
objLink.fireevent "onclick"

---

即使这不起作用，您也可以尝试以下方法（尽管不建议这样做，但是如果我们正确地进行计算，它将可以使用）。 我们尝试在对象上的某个位置找到位置，然后在该位置执行MouseClick操作。

set objLink = Browser("Create").Page("Create").WebTable("First").ChildItem(2, 1, "Link",0)
objLink.highlight

Set mobj = CreateObject("Mercury.DeviceReplay")
x = objLink.getRoProperty("abs_x")              'x-axis: Returns the position in pixels from the Top left corner of your monitor screen(not the parent object)
y = objLink.getRoProperty("abs_y")              'y-axis: Returns the position in pixels from the Top left corner of your monitor screen(not the parent object)
h = objLink.getRoProperty("height")             'returns height of the link object in pixels
w = objLink.getRoProperty("width")              'returns width of the link object in pixels

mobj.MouseClick Cint(x+h/4),Cint(y+w/4),1       'Try playing with the denominator 4. If you set it 2, it will attempt to click on the middle of the object.

Answer 2

只需单击“行”即可获得TR元素

RowNum=1 'The Row Number you want to click

'if the event handled over TR element then use without Replaytype =2
     Browser("Create").Page("Create").WebTable("First").WebElement("Html tag:=TR","Index:=" & RowNum-1).Click

'otherwise use with ReplayType = 2
     Setting.WebPackage("ReplayType") = 2
     Browser("Create").Page("Create").WebTable("First").WebElement("Html tag:=TR","Index:=" & RowNum-1).Click