SQL Server：如何替换回车符

Question

我正在使用以下过程将所有表中的所有carriage return符替换为' + ' ：

CREATE PROC SearchAndReplace
(
    @SearchStr nvarchar(100),
    @ReplaceStr nvarchar(100)
)
AS
BEGIN

    SET NOCOUNT ON

    DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110), @SQL nvarchar(4000), @RCTR int
    SET  @TableName = ''
    SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')
    SET @RCTR = 0

    WHILE @TableName IS NOT NULL
    BEGIN
        SET @ColumnName = ''
        SET @TableName = 
        (
            SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
            FROM    INFORMATION_SCHEMA.TABLES
            WHERE       TABLE_TYPE = 'BASE TABLE'
                AND QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
                AND OBJECTPROPERTY(
                        OBJECT_ID(
                            QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
                             ), 'IsMSShipped'
                               ) = 0
        )

        WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
        BEGIN
            SET @ColumnName =
            (
                SELECT MIN(QUOTENAME(COLUMN_NAME))
                FROM    INFORMATION_SCHEMA.COLUMNS
                WHERE       TABLE_SCHEMA    = PARSENAME(@TableName, 2)
                    AND TABLE_NAME  = PARSENAME(@TableName, 1)
                    AND DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar')
                    AND QUOTENAME(COLUMN_NAME) > @ColumnName
            )

            IF @ColumnName IS NOT NULL
            BEGIN
                SET @SQL=   'UPDATE ' + @TableName + 
                        ' SET ' + @ColumnName 
                        + ' =  REPLACE(' + @ColumnName + ', ' 
                        + QUOTENAME(@SearchStr, '''') + ', ' + QUOTENAME(@ReplaceStr, '''') + 
                        ') WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
                EXEC (@SQL)
                SET @RCTR = @RCTR + @@ROWCOUNT
            END
        END 
    END

    SELECT 'Replaced ' + CAST(@RCTR AS varchar) + ' occurence(s)' AS 'Outcome'
END
GO

创建过程之后，将其调用为：

EXEC SearchAndReplace 'GONNA', 'GOING'

表明：

结果------------------------------------------------- ---代替148发生

这是预期的结果。

---

问题：

1. 第一种情况：

   调用EXEC SearchAndReplace CHAR(10), ' + '导致以下结果：

   消息102，级别15，状态1，服务器WIN-M6K7U0AQLHJ，行1靠近“ 10”的语法不正确。

2. 第二种情况：

   调用EXEC SearchAndReplace 'CHAR(10)', ' + '会得到以下结果：

   结果------------------------------------------------- ---替换了0次

3. 第三种情况：

   调用EXEC SearchAndReplace 'CHAR(13)', ' + '会得到以下结果：

   结果------------------------------------------------- ---替换了0次

这意味着查询未能找到carriage return符并替换它们； 尽管我很确定，但是从CSV export ，由于数据库中确实存在carriage return ，因此导出的单元格被分成多行。

---

我是SQL Server新手，我无法确切知道自己在做什么错。

任何帮助将不胜感激。

Answer 1

尝试将Char(10)值存储在变量中，然后将该变量作为参数传递。

declare @tmp varchar(10)=CHAR(10)
EXEC SearchAndReplace @tmp, ' + '