在第一元素方式Perl中对哈希值进行排序

Question

我有一个哈希，我想以首先找到的元素的方式对其值进行排序。 在下面的脚本中，我按字母顺序对值进行了排序，但我真正想要的是根据先出现的值对它进行排序，例如，键0为ACBAD的值，第一个为A，因此对所有值进行排序首先，然后是C，然后是B，最后是D，我知道如何按字母顺序对其进行排序，但我不知道如何处理所需的订单。

#!/usr/bin/perl
use warnings;
use strict;
use List::MoreUtils;
use Tie::IxHash;    

my %KEY_VALUE;
#tie %KEY_VALUE,'Tie::IxHash';


my %KEY_VALUE= (
    0 => [ 'A', 'C', 'B', 'A' ,'D'],
    5 => [ 'D', 'F', 'E', 'F', 'F','E'],
    2 => [ 'Z', 'X', 'A', 'Y', 'X', 'Y', 'A' ],
    4 => [ 'E', 'R', 'M' ,'M','E'],
    3 => [ 'A', 'B', 'B', 'A' ],
    1 => [ 'C', 'C', 'F', 'E', 'C', 'E'],
    );

    #Code from Schwern user:14660
    # Iterate through the keys in numeric order.
    for my $key (sort {$a <=> $b } keys %KEY_VALUE)
    {
    # Get the value
    my $val = $KEY_VALUE{$key};

    # Sort it in place  #How to sort it in First Found Element instead of alphabetically increasing?

    @$val = sort { $a cmp $b } @$val;

    # Display it
    print "$key -> @$val\n";
    }

所需的输出是这样的，我想打印出排序的键和值。

    0 -> AACBD
    1 -> CCCFEE
    2 -> ZXXAAYY
    3 -> AABB
    4 -> EERMM
    5 -> DFFFEE

Answer 1

如果您将其视为排序问题，则可以在值及其所需顺序之间建立映射：

my @unsorted = qw( Z X X A Y X Y A );

my %order; @order{ reverse @unsorted } = reverse 0..$#unsorted;   # Z=>0, X=>1, A=>3, Y=>4
my @sorted = sort { $order{$a} <=> $order{$b} } @unsorted;        # ZXXXAAYY

但这实际上不是排序问题。 排序为O（N log N），但这可以在O（N）中完成。

my @unsorted = qw( Z X X A Y X Y A );

my %counts;
my @uniques = grep { !$counts{$_}++ } @unsorted;
my @sorted = map { ($_) x $counts{$_} } @uniques;                 # ZXXXAAYY

Answer 2

您得到了我认为想要的东西，非常简单。 您只需按照排序的键顺序遍历哈希，然后取消引用数组并对其进行排序。

#!/usr/bin/perl
use warnings;
use strict;

my %KEY_VALUE= (
    0 => [ 'A', 'C', 'B', 'A' ,'D'],
    5 => [ 'D', 'F', 'E', 'F', 'F','E'],
    2 => [ 'Z', 'X', 'A', 'Y', 'X', 'Y', 'A' ],
    4 => [ 'E', 'R', 'M' ,'M','E'],
    3 => [ 'A', 'B', 'B', 'A' ],
    1 => [ 'C', 'C', 'F', 'E', 'C', 'E'],
);

for my $key (sort { $a <=> $b } keys %KEY_VALUE) {
  print $key, " -> ", sort(@{ $KEY_VALUE{$key} }), "\n";
}

但这并不能提供您显示的结果。 请解释每个数组应该如何排序。 我以为您希望它们按字母顺序排序，但是在您的示例中情况并非如此。

我得到这个：

0 -> AABCD
1 -> CCCEEF
2 -> AAXXYYZ
3 -> AABB
4 -> EEMMR
5 -> DEEFFF

但您要求：

0 -> AACBD
1 -> CCCFEE
2 -> ZXXAAYY
3 -> AABB
4 -> EERMM
5 -> DFFFEE